複数条件の合計・件数｜エクセル関数超技

最終更新日：2013-06-09

複数条件の合計・件数

複数条件の合計、複数条件の件数を求める関数式です。

以下の表で説明します。

	A	B	C
1	品名	サイズ	売上
2	りんご	L	180
3	みかん	S	150
4	りんご	L	300
5	りんご	M	200
6	みかん	M	450
7	りんご	S	200
8	みかん	L	280
9	みかん	M	200
10	みかん	L	120

複数条件の合計

「みかん」の「M」の合計売上は

まず、2007以降ならSUMIFSが使えますので、問題はないと思います。
=SUMIFS(C2:C10,A2:A10,"みかん",B2:B10,"M")

SUMIFS(合計範囲,条件範囲1,条件値1,条件範囲2,条件値2),

しかし、2003ではSUMIFSは使えません。
では、どうするか、
=SUMPRODUCT((A2:A10="みかん")*(B2:B10="M")*C2:C10)

SUMPRODUCT(配列1,配列2,・・・)は、配列を乗算しその合計を求めます。

さらに別の方法も、配列を使用します。
{=SUM(IF((A2:A10="みかん")*(B2:B10="M"),C2:C10))}
=SUM(IF((A2:A10="みかん")*(B2:B10="M"),C2:C10))を入力し、Ctrl+Shift+Enterで、

Ctrl+Shift+Enterは、配列数式の入力です。

SUMIFS以外は、ちょっと理解しずらいと思います。

エクセルでは、論理値は、真(true)は1、偽(False)は0です。
つまり、１つでも条件を満たさない行は、*0が入るので、全て真の行のみ合計される訳です。
まあ、そんなものだと理解しておくのが良いと思います。

複数条件の件数

合計とほぼ同様です。
「みかん」の「M」の件数は

まず、2007以降ならCOUNTIFSが使えますので、問題はないと思います。
=COUNTIFS(A2:A10,"みかん",B2:B10,"M")

しかし、2003ではCOUNTIFSは使えません。
では、どうするか、
=SUMPRODUCT((A2:A10="みかん")*(B2:B10="M"))

SUMPRODUCT(配列1,配列2,・・・)は、配列を乗算しその合計を求めます。

さらに別の方法も、配列を使用します。
{=COUNT(IF((A2:A10="みかん")*(B2:B10="M"),1))}
=COUNT(IF((A2:A10="みかん")*(B2:B10="M"),1))を入力し、Ctrl+Shift+Enterで、

売上の合計の代わりに、「1」を指定しています。