連続数値部分を取り出し記号で連結

公開日：2020-03-24　最終更新日：2020-03-24

連続数値部分を取り出し記号で連結

文字と数値が混在している文字列から、連続している数値を取り出し、記号（-ハイフン等）で連結します。

ab123cde45fg678hij
↓
123-45-678
車中で思い浮かんだのだが、
関数でできるのか？

作成する関数の仕様

ab123cde45fg678hij
↓
123-45-678

いくつかの文字といくつかの数値が、交互に出てくる文字列から、
数値部分のみを取り出し、連続している数値は一塊として、記号(-)で連結します。
ab123cde45fg678hij
数値部分だけ取り出すと、
123 45 678
これを記号(-)で連結して、
123-45-678
このように変換する関数です。

スピル前：2019永続版まで

=SUBSTITUTE(
  TRIM(
    CONCAT(
      IF(
        ISNUMBER(MID(A1,ROW(OFFSET(A1,0,0,LEN(A1))),1)*1),
                 MID(A1,ROW(OFFSET(A1,0,0,LEN(A1))),1),
                 " ")
      )
    ),
  " ","-"
)

CONCAT関数を使っているので、Excel2019永続版以降

先のツイートのリプライにもある通り、これを実現する数式は何通りもあります。

スピル後：Office365

=SUBSTITUTE(
  TRIM(
    CONCAT(
      IF(
        ISNUMBER(MID(A1,SEQUENCE(LEN(A1)),1)*1),
                 MID(A1,SEQUENCE(LEN(A1)),1),
                 " ")
      )
    ),
  " ","-"
)

SEQUENCE関数を使っているので、Office365の2019年12月以降

スピル前からは、以下の部分が変更されています。
ROW(OFFSET(A1,0,0,LEN(A1)))
↓
SEQUENCE(LEN(A1))

LET関数：Office365 Insider 2020年3月現在

=LET(
  セル,A1,記号,"-",
  分割,MID(セル,SEQUENCE(LEN(セル)),1),
  数値,IF(ISNUMBER(分割*1),分割," "),
  SUBSTITUTE(TRIM(CONCAT(数値))," ",記号)
)

2020年3月現在、Office Insiderのみ

関数の作成手順

文字列長の数列を作成

C1=SEQUENCE(LEN(A1))

1文字ずつに分解

D1=MID(A1,C1#,1)

数値はそのまま、文字は半角スペース" "

E1=IF(ISNUMBER(D1#*1),D1#," ")

数字と半角スペース" "をすべて結合

F1=CONCAT(E1#)

前後のスペースを削除、中間のスペースは1つに

F2=TRIM(F1)

半角スペース" "を"-"に置換

F3=SUBSTITUTE(F2," ","-")

これらを一つの数式に全てネストしたものが前記の数式になります。
F2にはF2=の数式を入れ、F1にはF1=の数式を入れ…順にネストしていけば完成します。
1つの式で済んでいるのは良いのですが、、、
さすがにネストが深すぎて、解読困難になっています。

LET関数の作成手順

前記の個別の数式、

C1=SEQUENCE(LEN(A1))
D1=MID(A1,C1#,1)
E1=IF(ISNUMBER(D1#*1),D1#," ")

F1=CONCAT(E1#)
F2=TRIM(F1)
F3=SUBSTITUTE(F2," ","-")

このままLET関数の名前（変数）にしてしまうと、さすがに変数が多すぎて、ちっとも可読性が良くなりません。
そこで、上記のセルの数式のうち、他の数式で1回しか参照されていないものや、簡単な数式はまとめておきましょう。

C1はD1で1回しか使われていないので、
D1=MID(A1,SEQUENCE(LEN(A1)),1)

F1,F2はそれぞれ1回しか使われていないし簡単な数式なのでまとめてしまいましょう。
F3=SUBSTITUTE(TRIM(CONCAT(E1#)) ," ","-")

残ったのは、
D1=MID(A1,SEQUENCE(LEN(A1)),1)
E1=IF(ISNUMBER(D1#*1),D1#," ")
F3=SUBSTITUTE(TRIM(CONCAT(E1#)) ," ","-")
これをLET関数にします。
F3は最後の数式、D1とE1を名前（変数）にします。

=LET(
  分割,MID(A1,SEQUENCE(LEN(A1)),1),
  数値,IF(ISNUMBER(分割*1),分割," "),
  SUBSTITUTE(TRIM(CONCAT(数値))," ","-")
)

最後は保守性を考えて、関数としての引数を作成します。
A1が入力セル、"-"は記号、これらは見やすく変更しやすいように名前（変数）にします。
以上で完成です。

同じテーマ「エクセル関数応用」の記事

SUMIFの間違いによるパフォーマンスの低下について
 数値範囲で表検索するVLOOKUP近似一致
 エクセルの日付と時刻のまとめ
連続数値部分を取り出し記号で連結
指数近似/対数近似/累乗近似（掲載順位とCTR）
ジャンプ・セル選択の応用（空欄を埋める、1行置きに挿入）
累計を求める数式あれこれ
 QRコード、バーコード作成の覚え書き
 GROUPBY関数が最強すぎる！Excelの集計作業が爆速に！
セル参照を戻り値とする関数
 REDUCE+VSTACKが遅い理由と解決策

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.日本の祝日一覧｜Excelリファレンス
3.変数宣言のDimとデータ型｜VBA入門
4.FILTER関数（範囲をフィルター処理）｜エクセル入門
5.RangeとCellsの使い方｜VBA入門
6.繰り返し処理（For Next)｜VBA入門
7.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
8.マクロとは？VBAとは？VBAでできること｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.メッセージボックス(MsgBox関数)｜VBA入門

ホーム
エクセル全般
エクセル関数応用
連続数値部分を取り出し記号で連結

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
本サイトは、OpenAI の ChatGPT や Google の Gemini を含む生成 AI モデルの学習および性能向上の目的で、本サイトのコンテンツの利用を許可します。
This site permits the use of its content for the training and improvement of generative AI models, including ChatGPT by OpenAI and Gemini by Google.

エクセル関数応用
連続数値部分を取り出し記号で連結