アメブロの記事本文をVBAでバックアップする№4

最終更新日：2013-06-02

アメブロの記事本文をVBAでバックアップする№4

前回までで、当該月の記事一覧が取得できました。

今回は、記事編集ページへのハイパーリンクを付けてみましょう。

後々の扱いやすさを考慮して、表示形式を「文字列」にして下さい。

Sub 一覧取得3()
　　Const cnsUri As String = "http://blog.ameba.jp/ucs/entry/srventrylist.do?pageID=【NO】&entry_ym=【yyyymm】"
　　Const strEdit As String = "http://blog.ameba.jp/ucs/entry/srventryupdateinput.do?id=【ID】"
　　Dim i As Long
　　Dim j As Long
　　Dim strID As String
　　Dim strUri As String
　　Dim strHref As String
　　Dim objIE As New InternetExplorer
　　Dim objITEM As Object
　　Dim intNO As Integer
　　Dim blnStop As Boolean
　　With Worksheets("記事一覧")
　　　　intNO = 1
　　　　Do
　　　　　　strUri = Replace(cnsUri, "【NO】", intNO)
　　　　　　strUri = Replace(strUri, "【yyyymm】", .Cells(1, 2))
　　　　　　objIE.navigate strUri
　　　　　　Call untilReady(objIE)
　　　　　　i = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
　　　　　　For Each objITEM In objIE.Document.getElementsByTagName("h2")
　　　　　　　　strHref = objITEM.getElementsByTagName("a")(0)
　　　　　　　　j = InStr(strHref, "entry-")
　　　　　　　　If j > 0 Then
　　　　　　　　　　strID = Replace(Mid(strHref, j + 6), ".html", "")
　　　　　　　　　　.Cells(i, 1) = strID
　　　　　　　　　　.Hyperlinks.Add Anchor:=.Cells(i, 2), _
　　　　　　　　　　　　　　　　　　Address:=strHref, _
　　　　　　　　　　　　　　　　　　TextToDisplay:=objITEM.innertext
　　　　　　　　　　.Hyperlinks.Add Anchor:=.Cells(i, 3), _
　　　　　　　　　　　　　　　　　　Address:=Replace(strEdit, "【ID】", strID), _
　　　　　　　　　　　　　　　　　　TextToDisplay:="編集"
　　　　　　　　　　i = i + 1
　　　　　　　　End If
　　　　　　Next
　　　　　　blnStop = True
　　　　　　For Each objITEM In objIE.Document.getElementsByTagName("a")
　　　　　　　　If objITEM.innertext = "次へ" Then
　　　　　　　　　　blnStop = False
　　　　　　　　End If
　　　　　　Next
　　　　　　If blnStop = True Then
　　　　　　　　Exit Do
　　　　　　End If
　　　　　　intNO = intNO + 1
　　　　Loop
　　End With
　　objIE.Quit
　　Set objIE = Nothing
　　Set objITEM = Nothing
　　MsgBox "オワッタッタッタッタッター"
End Sub

http://blog.ameba.jp/ucs/entry/srventryupdateinput.do?id=【ID】

これが記事編集ページのURLになります。

このID部分を取得したIDで置き換えて、

「編集」の文字表記に、ハイパーリンクを付けてセルに設定しています。

ここは簡単ですね。

いよいよ大詰め、記事本文のバックアップに入ります。

アメブロの記事本文をVBAでバックアップする №1 №2 №3 №4 №5 №6