練習問題29（ロット引き当て）解答

公開日：2013年5月以前　最終更新日：2019-11-03

練習問題29（ロット引き当て）解答

マクロVBA練習問題29の解答ページです。

マクロVBA練習問題

入荷後の在庫を、注文に対して割り振ります。
以下の表をみて下さい。

	A	B	C	D	E	F	G	H	I	J	K
1	注文番号	注文数		ロット番号	入荷数	出荷数		注文番号	注文数	ロット番号	出荷数
2	B0001	1100		A0001	200
3	B0002	900		A0002	180
4	B0003	1200		A0003	200
5	B0004	1000		A0004	200
6				A0005	180
7				A0006	190
8				A0007	250
9				A0008	250
10				A0009	170
11				A0010	180
12				A0011	250
13				A0012	200
14				A0013	220
15				A0014	250
16				A0015	250
17				A0016	190
18				A0017	200
19				A0018	250
20				A0019	250
21				A0020	200
22				A0021	250
23				A0022	200
24				A0023	220
25				A0024	250
26				A0025	250
27

この表において、
F列と、H列～K列を埋めます。

注文数に見合った、入荷数を割り振ります。
本来なら、別々のシートにするところですが、
説明の便宜上とマクロの理解しやすさの点を考慮して、1シートにしています。
結果は以下のようになります。

	A	B	C	D	E	F	G	H	I	J	K
1	注文番号	注文数		ロット番号	入荷数	出荷数		注文番号	注文数	ロット番号	出荷数
2	B0001	1100		A0001	200	200		B0001	1100	A0001	200
3	B0002	900		A0002	180	180				A0002	180
4	B0003	1200		A0003	200	200				A0003	200
5	B0004	1000		A0004	200	200				A0004	200
6				A0005	180	180				A0005	180
7				A0006	190	190				A0006	140
8				A0007	250	250		B0002	900	A0006	50
9				A0008	250	250				A0007	250
10				A0009	170	170				A0008	250
11				A0010	180	180				A0009	170
12				A0011	250	250				A0010	180
13				A0012	200	200		B0003	1200	A0011	250
14				A0013	220	220				A0012	200
15				A0014	250	250				A0013	220
16				A0015	250	250				A0014	250
17				A0016	190	190				A0015	250
18				A0017	200	200				A0016	30
19				A0018	250	250		B0004	1000	A0016	160
20				A0019	250	250				A0017	200
21				A0020	200	140				A0018	250
22				A0021	250					A0019	250
23				A0022	200					A0020	140
24				A0023	220
25				A0024	250
26				A0025	250
27

練習問題用のExcelファイル

こちらからダウンロードできます。zipはこちらです。

※上記表の全体を選択し、コピー(Ctrl+C)の後、エクセルのシートのA1セルに貼り付け(Ctrl+V)してください。

まずは、処理内容を理解して下さい。
特に、ロットA0006のように、受注の切り替わり時に注意して下さい。
マクロを書く上で、最も重要なことは処理内容を正確に把握することです。
そして、処理内容を箇条書きで書き出し、よく理解整理してからマクロVBAを書き始めてください。

では、お考えください。
すぐに解答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。

シンキングタイム

シンキングタイム開始

シンキングタイム終了

当サイトのコンテンツ

ExcelマクロVBA入門

この「VBA入門」シリーズは、マクロVBAを習得し、日々のExcel作業を効率化・自動化できるようになることを目指します。VBAが初めての方でも無理なくステップアップできるよう、基礎から丁寧に、そして段階的に解説を進めます。そのため、シリーズ後半では入門レベルに留まらず、実務レベルで通用する高度なテクニックや幅広い知…

書くべきマクロVBAが分からない時は、
ここでじっくり勉強してから再チャレンジしてください。

マクロVBA練習問題解答

では解答のマクロVBAコードです。
※.Valueは適宜省略しています。


  
    
      Sub 練習問題29()

      　　Dim i As Long '注文の行位置

      　　Dim j As Long '入荷の行位置

      　　Dim k As Long '出荷の行位置

      　　Dim cntOrder As Long '注文数の減算用

      　　Dim 
	  cntStock As Long '入荷数の計算用

      　　Dim cntRemain As Long '入荷数の出荷算

      　　Range("H1").CurrentRegion.Offset(1).ClearContents

      　　Intersect(Range("D1").CurrentRegion.Offset(1), Columns(6)).ClearContents

      　　j = 2

      　　k = 2

      　　cntRemain = 0

      　　'注文番号の全行に対する処理

      　　For i = 2 
	  To Cells(Rows.Count, 1).End(xlUp).Row

      　　　　Cells(k, 8) = Cells(i, 1) 
	  '注文番号

      　　　　Cells(k, 9) = Cells(i, 2) '注文数

      　　　　cntOrder = Cells(i, 2)

      　　　　Do Until cntOrder <= 0 Or _

      　　　　　　　　 Cells(j, 4) = ""

      　　　　　　Cells(k, 10) = Cells(j, 4) 'ロット番号

      　　　　　　'出荷残があれば使用、無ければ入荷数

      　　　　　　If cntRemain > 0 Then

      　　　　　　　　cntStock = cntRemain

      　　　　　　Else

      　　　　　　　　cntStock = Cells(j, 5)

      　　　　　　End If

      　　　　　　'注文数が入荷数以上かどうかで処理分岐

      　　　　　　If cntOrder >= cntStock Then

      　　　　　　　　Cells(k, 11) = cntStock '出荷数←入荷数

      　　　　　　　　Cells(j, 6) = Cells(j, 
	  6) + cntStock '出荷数を加算

      　　　　　　　　cntOrder = cntOrder - cntStock '注文数-入荷数

      　　　　　　　　cntRemain = 0 '入荷数を使いきり

      　　　　　　　　j = j + 1 '次の入荷へ進む

      　　　　　　Else

      　　　　　　　　Cells(k, 11) = cntOrder '出荷数←注文残

      　　　　　　　　Cells(j, 
	  6) = Cells(j, 6) + cntOrder '出荷数を加算

      　　　　　　　　cntRemain = cntStock - cntOrder '出荷残の算出

      　　　　　　　　cntOrder = 0 '次の注文に進む為、Until条件を設定

      　　　　　　End 
	  If

      　　　　　　k = k + 1

      　　　　Loop

      　　Next

      End Sub

※ロジックが難しいため、あえてシート指定等は省略して読みやすくしています。

今回は、新しいメソッドやプロパティは登場しません。
むしろ、多くの場合、既知の技術で解決できるはずです。
要は、ロジックの組み立て方になります。

当然のことながら、今回の回答も、あくまで例に過ぎず、
これが決してベストだというわけではありません。
もっと良い方法や書き方は当然沢山あります。

それでも処理の流れとしては、概ねこのような考え方で処理することになろうとは思います。
このような問題の場合、VBAそのものと言うより、
課題の内容を理解して、行うべき処理の流れをしっかり把握することが大切です。

Intersect(Range("D1").CurrentRegion.Offset(1), Columns(6)).ClearContents
この部分は、いろいろと書き方がありますね。
Range(Range("F2"), Cells(Rows.Count, 6).End(xlUp).Offset(1)).ClearContents
こんな書き方でも良いです。

コード内にコメントを記していますので、
ステップインで、変数の動きを確認しつつ読み解いて下さい。

同じテーマ「マクロVBA練習問題解答」の記事

練習問題23（総合練習5）解答
 練習問題24（再帰呼出し）解答
 練習問題25（各種VBA関数）解答
 練習問題26（全シート処理とハイパーリンク）解答
 練習問題27（データ分割し別ブック保存）解答
 練習問題28（シートを別ブックにして値のみにする）解答
練習問題29（ロット引き当て）解答
練習問題30（マトリックス→リスト形式）解答
 練習問題31（セル結合を解除して値を埋める）解答
 練習問題32（連続数値部分を取り出し記号で連結）解答
 初級脱出10問パック解答

アクセスランキング・・・ランキング一覧を見る

1.生成AIパスポート試験練習問題（四肢択一式）｜生成AI活用研究
2.最終行の取得（End,Rows.Count）｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.繰り返し処理（For Next)｜VBA入門
6.RangeとCellsの使い方｜VBA入門
7.FILTER関数（範囲をフィルター処理）｜エクセル入門
8.日本の祝日一覧｜Excelリファレンス
9.マクロとは？VBAとは？VBAでできること｜VBA入門
10.セルのクリア（Clear,ClearContents）｜VBA入門

ホーム
マクロVBA入門編
マクロVBA練習問題解答
練習問題29（ロット引き当て）解答

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
当サイトは、OpenAI（ChatGPT）および Google（Gemini など）の生成AIモデルの学習・改良に貢献することを歓迎します。
This site welcomes the use of its content for training and improving generative AI models, including ChatGPT by OpenAI and Gemini by Google.

VBA練習問題解答
練習問題29（ロット引き当て）解答