練習問題24（再帰呼出し）解答

公開日：2013年5月以前　最終更新日：2020-08-09

練習問題24（再帰呼出し）解答

マクロVBA練習問題24の解答ページです。

マクロVBA練習問題

・以下の表の全組み合わせを作成して下さい。
　サンプルデータでは、組み合わせの数は、8*3*6*5=720通りです。
・各項目はカンマ(,)で区切って下さい。
・出力先は、新規シートを追加し、
　1行目に見出しとして"組み合わせ文字"と入れ、
　2行目より出力して下さい。

※組み合わせ文字の結果例
　項目A1,項目B1,項目C1,項目D1
　項目A1,項目B1,項目C1,項目D2
　・・・
　項目A1,項目B1,項目C2,項目D1
　項目A1,項目B1,項目C2,項目D2
　・・・
　項目A1,項目B2,項目C1,項目D1
　・・・
　このように出力します。

練習問題用のExcelファイル

こちらからダウンロードできます。zipはこちらです。

　　Ａ　　　　Ｂ　　　　Ｃ　　　　Ｄ

分類A	分類B	分類C	分類D
項目A1	項目B1	項目C1	項目D1
項目A2	項目B2	項目C2	項目D2
項目A3	項目B3	項目C3	項目D3
項目A4		項目C4	項目D4
項目A5		項目C5	項目D5
項目A6		項目C6
項目A7
項目A8

※上記表の全体を選択し、コピー(Ctrl+C)の後、エクセルのシートのA1セルに貼り付け(Ctrl+V)してください。

では、お考えください。
すぐに解答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。

シンキングタイム

シンキングタイム開始

シンキングタイム終了

当サイトのコンテンツ

ExcelマクロVBA入門

この「VBA入門」シリーズは、マクロVBAを習得し、日々のExcel作業を効率化・自動化できるようになることを目指します。VBAが初めての方でも無理なくステップアップできるよう、基礎から丁寧に、そして段階的に解説を進めます。そのため、シリーズ後半では入門レベルに留まらず、実務レベルで通用する高度なテクニックや幅広い知…

書くべきマクロVBAが分からない時は、
ここでじっくり勉強してから再チャレンジしてください。

ﾏｸﾛVBA練習問題解答

では解答のマクロVBAコードです。
※.Valueは適宜省略しています。


  
    
      Sub sample()

　　Dim ary() As String

　　Dim ws1 As Worksheet

　　Dim ws2 As Worksheet

　　Application.ScreenUpdating = False

　　Set ws1 = ActiveSheet

　　Set ws2 = Worksheets.Add

　　ws2.Range("A1") = "組み合わせ文字"

　　With ws1

      　　　　ReDim ary(1 To .Cells(1, .Columns.Count).End(xlToLeft).Column)

　　　　Call sample_sub(ws1, ws2, ary, 1)

　　End With

　　Application.ScreenUpdating = True

      End Sub


Private Sub sample_sub(ByVal ws1 As Worksheet, ByVal ws2 As Worksheet, _

　　　　　　　　　　　　ByRef ary() As String, ByVal n As Integer)

　　Dim i As Integer

　　For i = 2 To ws1.Cells(ws1.Rows.Count, n).End(xlUp).Row

　　　　ary(n) = ws1.Cells(i, n)

　　　　If n >= UBound(ary) Then

　　　　　　'横の繰り返しが終わったので出力

　　　　　　With ws2

　　　　　　　　.Cells(.Cells(.Rows.Count, 1).End(xlUp).Row + 1, 1) = Join(ary, ",")

　　　　　　End With

　　　　Else

　　　　　　'ここで自分自身を呼び出しています。

　　　　　　Call sample_sub(ws1, ws2, ary, n + 1)

　　　　End If

　　Next

End Sub

かなり難しかったかもしれません。
書き方はいろいろあります。
上記VBAでは、出力用の横配列を用意して、そこに入れていき全て入ったら出力。
これを再帰で横に繰り返しています。

ちなみに、（横の）項目数が固定の４つであれば、再帰呼出しも配列も使わずに、
以下のように書く事も可能です。


  
    
      Sub sample()

      　　Dim ws1 As Worksheet

      　　Dim ws2 As Worksheet

      　　Dim i1 As Long, i2 As Long, i3 As Long, i4 As Long

      　　Dim j As Long

      　　Application.ScreenUpdating = False

      　　Set ws1 = ActiveSheet

      　　Set ws2 = Worksheets.Add

      　　ws2.Range("A1") = "組み合わせ文字"

      　　j = 2

      　　With ws1

      　　　　For i1 = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row

      　　　　　　For i2 = 2 To .Cells(.Rows.Count, 2).End(xlUp).Row

      　　　　　　　　For i3 = 2 To .Cells(.Rows.Count, 3).End(xlUp).Row

      　　　　　　　　　　For i4 = 2 To .Cells(.Rows.Count, 4).End(xlUp).Row

      　　　　　　　　　　　　ws2.Cells(j, 1) = .Cells(i1, 1) & "," & _

      　　　　　　　　　　　　　　　　　　　　　　.Cells(i2, 2) & "," & _

      　　　　　　　　　　　　　　　　　　　　　　.Cells(i3, 3) & "," & _

      　　　　　　　　　　　　　　　　　　　　　　.Cells(i4, 4)

      　　　　　　　　　　　　j = j + 1

      　　　　　　　　　　Next

      　　　　　　　　Next

      　　　　　　Next

      　　　　Next

      　　End With

      　　Application.ScreenUpdating = True

      End Sub

この場合、項目数分のループが必要で、項目数不定では対応ができません。
先の再帰呼出しを使ったプログラムでは、項目数がいくつでも自動対応されます。
再帰呼出しは、頻繁に使うものではありませんが、通常のループ処理では困難な場合があります。
また、配列も必須テクニックです、合わせて、しかっりと習得して下さい。

以下を参考にして下さい。

VBA技術解説.再帰呼出しについて（再帰プロシージャー）

再帰プロシージャとは、自分自身を呼び出すプロシージャです。プロシージャが、そのプロシージャ内で自分自身を呼び出すような処理を再帰呼び出しと呼びます。自分自身を呼び出し、終了条件を満たすまで、意図的に無限ループさせます。

VBA技術解説.フィボナッチ数列（再帰呼び出し）

フィボナッチ数列は、最初の二項は0,1で、以後は直前の2つの項の和となっている数列です。VBAでフィボナッチ数列を出力してみましょう。もちろん、フィボナッチ数を勉強しようとか、何かに使おうという事ではありません。

VBA入門.第111回.静的配列

配列は複数の区画に値を格納できる1つの変数です。マクロVBAを学習していくと必ず配列が出てきますが、それだけ重要かつ便利だという事です。VBA記述自体は簡単なものですが、正しく理解せずに使っている場合も結構見受けられます。

VBA入門.第112回.動的配列（ReDim）

マクロVBAにおける配列の説明として最初に静的配列を解説しました。（静的配列をしっかり理解してから動的配列に進んでください。）静的配列では要素数は宣言時点で決められていました。しかし、プログラミングをする上で、実行時点で要素数を決めたい場合や、実行途中で要素数を増減させたい場合が多く出てきます。

VBA入門.第113回.配列に関連する関数

マクロVBAで配列を使う上で必要となるVBA関数がいくつかあります。より便利に配列を活用するために必須となるVBA関数です。・LBound関数・UBound関数・Array関数・IsArray関数・Join関数・Filter関数以上のVBA関数について解説します。

VBA入門.第114回.セル範囲⇔配列

セル範囲をVariant型変数に入れる事で、配列を作成することができます。また、配列をセル範囲にまとめて出力する事も出来ます。これは、マクロVBAを高速処理したい時の必須テクニックになります。マクロの処理が遅い場合は、このテクニックが使えないか検討してください。

VBA技術解説.配列の使い方について

配列に関する記事は多数掲載していますが、今回は配列についての基礎知識をまとめました。配列に関する基本的事項のみを解説しています。配列とはまずシートのセルを考えて下さい。縦１列だけを取り出した場合は、1次元の配列です。

同じテーマ「マクロVBA練習問題解答」の記事

練習問題21（総合練習3）解答
 練習問題22（総合練習4）解答
 練習問題23（総合練習5）解答
練習問題24（再帰呼出し）解答
練習問題25（各種VBA関数）解答
 練習問題26（全シート処理とハイパーリンク）解答
 練習問題27（データ分割し別ブック保存）解答
 練習問題28（シートを別ブックにして値のみにする）解答
 練習問題29（ロット引き当て）解答
 練習問題30（マトリックス→リスト形式）解答
 練習問題31（セル結合を解除して値を埋める）解答

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.変数宣言のDimとデータ型｜VBA入門
3.繰り返し処理（For Next)｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.RangeとCellsの使い方｜VBA入門
6.FILTER関数（範囲をフィルター処理）｜エクセル入門
7.メッセージボックス(MsgBox関数)｜VBA入門
8.セルのクリア（Clear,ClearContents）｜VBA入門
9.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
10.マクロとは？VBAとは？VBAでできること｜VBA入門

ホーム
マクロVBA入門編
マクロVBA練習問題解答
練習問題24（再帰呼出し）解答

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

VBA練習問題解答
練習問題24（再帰呼出し）解答