練習問題30（マトリックス→リスト形式）解答

公開日：2013年5月以前　最終更新日：2019-11-03

練習問題30（マトリックス→リスト形式）解答

マクロVBA練習問題30の解答ページです。

マクロVBA練習問題

売上と仕入の、支店別年度別のマトリックス表があります。
これをリスト形式（データベース形式）のデータに変換してください。
以下の表をみて下さい。
縦横の項目の交点に数値が入っていて、ピボットテーブルのようなマトリックス表になっています。
これを1行1件のデータに変換してください。
いわゆる、「リスト形式」「データベース形式」に変換するという事です。

		A支店			B支店			C支店
		売上	仕入	仕入比	売上	仕入	仕入比	売上	仕入	仕入比
2017年	実績	1419	752	53.0%	2167	1235	57.0%	1828	1169	63.9%
2017年	予算	1079	517	47.9%	1160	730	62.9%	1653	909	55.0%
2018年	売上	1328	717	54.0%	1666	949	57.0%	1932	1120	58.0%
2018年	仕入	1305	835	64.0%	2705	1406	52.0%	1538	922	59.9%
2019年	売上	1097	658	60.0%	2093	1318	63.0%	1518	819	54.0%
2019年	仕入	1385	803	58.0%	2599	1273	49.0%	2247	1325	59.0%

※上記表の全体を選択し、コピー(Ctrl+C)の後、エクセルのシートのA1セルに貼り付け(Ctrl+V)してください。

練習問題用のExcelファイル

こちらからダウンロードできます。zipはこちらです。

このような表はエクセルを使っている現場では良く見かけます。
画面で見たり、印刷するには良いのですが、
このデータを他で使おうとした時に不便を感じたことはあるのではないでしょうか。
そこで、関数等で扱いやすいように以下のようなリスト形式（データベース形式）に変換します。

支店	年度	科目	区分	金額
A支店	2017年	売上	実績	1419
A支店	2017年	仕入	実績	752
B支店	2017年	売上	実績	2167
B支店	2017年	仕入	実績	1235
C支店	2017年	売上	実績	1828
C支店	2017年	仕入	実績	1169
A支店	2017年	売上	予算	1079
A支店	2017年	仕入	予算	517
B支店	2017年	売上	予算	1160
B支店	2017年	仕入	予算	730
C支店	2017年	売上	予算	1653
C支店	2017年	仕入	予算	909
A支店	2018年	売上	売上	1328
A支店	2018年	仕入	売上	717
B支店	2018年	売上	売上	1666
B支店	2018年	仕入	売上	949
C支店	2018年	売上	売上	1932
C支店	2018年	仕入	売上	1120
A支店	2018年	売上	仕入	1305
A支店	2018年	仕入	仕入	835
B支店	2018年	売上	仕入	2705
B支店	2018年	仕入	仕入	1406
C支店	2018年	売上	仕入	1538
C支店	2018年	仕入	仕入	922
A支店	2019年	売上	売上	1097
A支店	2019年	仕入	売上	658
B支店	2019年	売上	売上	2093
B支店	2019年	仕入	売上	1318
C支店	2019年	売上	売上	1518
C支店	2019年	仕入	売上	819
A支店	2019年	売上	仕入	1385
A支店	2019年	仕入	仕入	803
B支店	2019年	売上	仕入	2599
B支店	2019年	仕入	仕入	1273
C支店	2019年	売上	仕入	2247
C支店	2019年	仕入	仕入	1325

新規シート「練習30_解答」を挿入し、A1セルか上記表を作成してください。
出力する科目は、「売上」「仕入」だけにして、「仕入比」は不要です。

では、お考えください。
すぐに解答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。

シンキングタイム

シンキングタイム開始

シンキングタイム終了

当サイトのコンテンツ

ExcelマクロVBA入門

この「VBA入門」シリーズは、マクロVBAを実務で自在に使いこなし業務を効率化・自動化できるようになることを目的としています。始めはより詳しく丁寧に解説しつつ少しずつ難易度を上げることで無理なく学習を進められるようにしています。ただし入門といっても、後半にはかなり高度な内容にも触れています。

書くべきマクロVBAが分からない時は、
ここでじっくり勉強してから再チャレンジしてください。

マクロVBA練習問題解答

では解答のマクロVBAコードです。
※.Valueは適宜省略しています。


  
    
      Sub 練習問題30()

　　Dim ws1 As Worksheet

　　Set ws1 = Worksheets("練習30")

　　Dim ws2 As Worksheet

　　Set ws2 = getSheet("練習30_解答")

　　With ws2

　　　　.Cells.Clear

　　　　.Range("A1") = "支店"

　　　　.Range("B1") = "年度"

　　　　.Range("C1") = "科目" '売上/仕入

　　　　.Range("D1") = "区分" '実績予算

　　　　.Range("E1") = "金額"

　　　　.Select

　　End With

　　

　　Dim iRow As Long, iCol As Long '入力シートの行列

　　Dim rMax As Long, cMax As Long '入力シートの最大行列

　　rMax = ws1.Cells(ws1.Rows.Count, 2).End(xlUp).Row

　　cMax = ws1.Cells(2, ws1.Columns.Count).End(xlToLeft).Column

　　Dim i As Long '出力シートの行

　　i = 2

　　For iRow = 3 To rMax

      　　　　For iCol = 3 To cMax

      　　　　　　'Ifでも良いが、拡張性を考えてSelect Caseにしています

      　　　　　　Select Case ws1.Cells(2, iCol).Value

      　　　　　　　　Case "売上", "仕入"

　　　　　　　　　　ws2.Cells(i, 1).Value = ws1.Cells(1, iCol).MergeArea.Item(1)

　　　　　　　　　　ws2.Cells(i, 2).Value = ws1.Cells(iRow, 1).MergeArea.Item(1)

　　　　　　　　　　ws2.Cells(i, 3).Value = ws1.Cells(2, iCol).Value

　　　　　　　　　　ws2.Cells(i, 4).Value = ws1.Cells(iRow, 2).Value

　　　　　　　　　　ws2.Cells(i, 5).Value = ws1.Cells(iRow, iCol).Value

　　　　　　　　　　i = i + 1

　　　　　　End Select

　　　　Next

　　Next

End Sub


'シート名が無ければ挿入、あればそれを返す

Function getSheet(ByVal argName As String) As Worksheet

　　Dim ws As Worksheet

　　For Each ws In Worksheets

　　　　If LCase(StrConv(ws.Name, vbNarrow)) = LCase(StrConv(argName, vbNarrow)) Then

　　　　　　'存在した場合は削除してExit Forでも良い

　　　　　　Set getSheet = ws

　　　　　　Exit Function

　　　　End If

　　Next

　　'シート挿入して名前変更

　　Set getSheet = Worksheets.Add

　　getSheet.Name = argName

      End Function

上記VBAの解説は不要でしょう。
マクロVBA内の洋書にはコメントを入れていますので、じっくり読み解いてみてください。

練習問題をこの30問まで順に進めてきた方であれば、このVBAを読むことは難しくないでしょう。
難しい技術は何も使っていません。
マクロVBAをある程度覚えたら、後はVBAをどこまでスムーズに書けるようになるかが問題です。
これを習得するには、繰り返し練習以外には方法がありません。
いくら書籍やWEBページを読んでも、実際にVBAをスラスラ書けるようにはならないと思います。
実際に手を動かして、マクロVBAを書く練習をしてください。

同じテーマ「マクロVBA練習問題解答」の記事

練習問題23（総合練習5）解答

マクロVBA練習問題23の解答ページです。マクロVBA練習問題・A2セルに日付、B2セルに名前を指定します。この条件に合うデータを、シート「練習23_データ」から抜出し、５行目以降に表示して下さい。

練習問題24（再帰呼出し）解答

マクロVBA練習問題24の解答ページです。マクロVBA練習問題・以下の表の全組み合わせを作成して下さい。サンプルデータでは、組み合わせの数は、8*3*6*5=720通りです。・各項目はカンマ(,)で区切って下さい。

練習問題25（各種VBA関数）解答

マクロ練習問題25の解答ページです。マクロVBA練習問題・以下の表において、課題に従って元データより回答欄に出力して下さい。※１問目なら、回答欄に"Excelマクロ(vba)練習"と出力する。

練習問題26（全シート処理とハイパーリンク）解答

マクロVBA練習問題26の解答ページです。マクロVBA練習問題全シートのハイパーリンク付き一覧を先頭シートに作成します。現在のブックの先頭に新規シートを追加し、既存シートのシート名一覧をハイパーリンク付きで作成して下さい。

練習問題27（データ分割し別ブック保存）解答

マクロVBA練習問題27の解答ページです。マクロVBA練習問題アクティブブックのアクティブシートのA列に担当、B列に支店が入っています。支店ごとのブックを作成して下さい。作成したブックの保存先は、アクティブブックと同一フォルダとして下さい。

練習問題28（シートを別ブックにして値のみにする）解答

マクロVBA練習問題28の解答ページです。マクロVBA練習問題アクティブブックにはシートが複数（Sheet1,Sheet2,Sheet3）あります。Sheet1だけを別ブックにして、計算式を抜き（値だけに）にしてから保存して下さい。

練習問題29（ロット引き当て）解答

マクロVBA練習問題29の解答ページです。マクロVBA練習問題入荷後の在庫を、注文に対して割り振ります。以下の表をみて下さい。この表において、F列と、H列～K列を埋めます。注文数に見合った、入荷数を割り振ります。

練習問題30（マトリックス→リスト形式）解答
練習問題31（セル結合を解除して値を埋める）解答

マクロVBA練習問題31の解答ページです。マクロVBA練習問題セル結合されていると、マクロVBAでは扱いにくい場合が多々あります。そこで、セル結合を解除して、結合されていたセル範囲に同じ値を入れたいと思います。

練習問題32（連続数値部分を取り出し記号で連結）解答

マクロVBA練習問題32の解答ページです。マクロVBA練習問題文字列処理の応用問題です。ab123cde45fg678hij 123-45-678 いくつかの文字といくつかの数値が、交互に出てくる文字列から、数値部分のみを取り出し、連続している数値は一塊として、記号(-)で連結します。

初級脱出10問パック解答

マクロVBA練習問題初級脱出10問パックの解答ページです。解答コード掲載箇所へジャンプマクロVBA練習問題初級を脱出するためのVBA問題を10問1パックにしました。ページ内目次問題1：文字列結合問題2：文字列分割問題3：消費税計算問題4：数値合計とMsgBox 問題5：セル範囲のコピー問題6：セル範囲…

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.繰り返し処理（For Next)｜VBA入門
5.RangeとCellsの使い方｜VBA入門
6.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
7.セルのクリア（Clear,ClearContents）｜VBA入門
8.メッセージボックス(MsgBox関数)｜VBA入門
9.条件分岐（Select Case）｜VBA入門
10.ブック・シートの選択（Select,Activate）｜VBA入門

ホーム
マクロVBA入門編
マクロVBA練習問題解答
練習問題30（マトリックス→リスト形式）解答

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

VBA練習問題解答
練習問題30（マトリックス→リスト形式）解答