練習問題32（連続数値部分を取り出し記号で連結）解答

公開日：2013年5月以前　最終更新日：2020-03-24

練習問題32（連続数値部分を取り出し記号で連結）解答

マクロVBA練習問題32の解答ページです。

マクロVBA練習問題

文字列処理の応用問題です。

ab123cde45fg678hij
↓
123-45-678

いくつかの文字といくつかの数値が、交互に出てくる文字列から、
数値部分のみを取り出し、連続している数値は一塊として、記号(-)で連結します。
ab123cde45fg678hij
数値部分だけ取り出すと、
123 45 678
これを記号(-)で連結して、
123-45-678
このように変換してください。

練習問題用のExcelファイル

こちらからダウンロードできます。zipはこちらです。

この問題に対するシートはありません。

メインのプロシージャーから文字列を渡して、返還後の文字列を返す形であればどのような形でも構いません。

VBAコードの書き方は何通りもあります。
回答サンプルでは、
・正規表現
・For...Next
・再帰プロシージャー
この3パターンを用意しました。

では、お考えください。
すぐに解答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。

シンキングタイム

シンキングタイム開始

シンキングタイム終了

当サイトのコンテンツ

ExcelマクロVBA入門

この「VBA入門」シリーズは、マクロVBAを習得し、日々のExcel作業を効率化・自動化できるようになることを目指します。VBAが初めての方でも無理なくステップアップできるよう、基礎から丁寧に、そして段階的に解説を進めます。そのため、シリーズ後半では入門レベルに留まらず、実務レベルで通用する高度なテクニックや幅広い知…

書くべきマクロVBAが分からない時は、
ここでじっくり勉強してから再チャレンジしてください。

マクロVBA練習問題解答

では解答のマクロVBAコードです。

正規表現


  
    
      Sub 練習問題32_1()

      　　Dim rtn As String

      　　rtn = fnc1("ab123cde45fg678hij", "-")

      　　MsgBox rtn

      End Sub


      Function fnc1(ByVal str As String, _

      　　　　　　　ByVal mark As String)

      　　With CreateObject("VBScript.RegExp")

      　　　　.Pattern = "\D+"

      　　　　.Global = True

      　　　　fnc1 = Replace(Trim(.Replace(str, " ")), " ", mark)

      　　End With

      End Function

上記VBAでは、短いVBAコードで実現するように、
Withを使ったり、最後もネストで1行で済ませています。
もちろん変数に入れて、順に書いて行く方が読みやすく分かり易い場合も多いので、あくまで短くした場合の書き方という事です。

正規表現については、以下で詳しく解説していますので参考にしてください。

VBAで正規表現を利用する（RegExp）

正規表現は複雑なパターンマッチングとテキストの検索置換するためのツールです、マクロVBAで正規表現を使う場合はRegExpオブジェクトを使用します、RegExpは、VBScriptに正規表現として用意されているオブジェクトです。VBScript廃止に向けて、VBAプロジェクトを対応させる方法 Prepareyour…

For...Next


  
    
      Sub 練習問題32_2()

　　Dim rtn As String

　　rtn = fnc2("ab123cde45fg678hij", "-")

　　MsgBox rtn

End Sub


Function fnc2(ByVal str As String, _

　　　　　　　ByVal mark As String) As String

　　Dim rtn As String

　　Dim i As Long

　　For i = 1 To Len(str)

　　　　If IsNumeric(Mid(str, i, 1)) Then

　　　　　　rtn = rtn & Mid(str, i, 1)

　　　　Else

　　　　　　If Right(rtn, 1) <> mark Then

　　　　　　　　rtn = rtn & mark

      　　　　　　End If

　　　　End If

　　Next

　　If Left(rtn, 1) = mark Then

　　　　rtn = Mid(rtn, 2)

　　End If

　　If Right(rtn, 1) = mark Then

　　　　rtn = Left(rtn, Len(rtn) - 1)

      　　End If

　　fnc2 = rtn

End Function

先の正規表現のように、半角スペースにしておいて、Trim後に置換する方法を用いれば、コード量はかなり減ります。
上記は、あえて別の方法でのサンプルになります。

再帰プロシージャー


  
    
      Sub 練習問題32_3()

      　　Dim rtn As String

      　　rtn = fnc3("ab123cde45fg678hij", "-")

      　　MsgBox rtn

      End Sub


      Function fnc3(ByVal str As String, _

      　　　　　　　ByVal mark As String, _

      　　　　　　　Optional ByRef num = 1) As String

      　　Dim rtn As String

      　　If IsNumeric(Mid(str, num, 1)) Then

      　　　　rtn = rtn & Mid(str, num, 1)

      　　Else

      　　　　If num > 1 Then

      　　　　　　If Mid(str, num - 1) Like "#*#*" Then

      　　　　　　　　rtn = mark

      　　　　　　End If

      　　　　End If

      　　End If

      　　If num >= Len(str) Then Exit Function

      　　fnc3 = rtn & fnc3(str, mark, num + 1)

      End Function


  
    
      Sub 練習問題32_4()

      　　Dim rtn As String

      　　Call fnc4("ab123cde45fg678hij", "-", rtn)

      　　MsgBox rtn

      End Sub


      Sub fnc4(ByVal str As String, _

      　　　　 ByVal mark As String, _

      　　　　 ByRef rtn As String, _

      　　　　 Optional ByRef num = 1)

      　　If IsNumeric(Mid(str, num, 1)) Then

      　　　　rtn = rtn & Mid(str, num, 1)

      　　　　If Mid(str, num) Like "#[!0-9]*#*" Then

      　　　　　　rtn = rtn & mark

      　　　　End If

      　　End If

      　　If num >= Len(str) Then Exit Sub

      　　Call fnc4(str, mark, rtn, num + 1)

      End Sub

どちらも再帰プロシージャーですが、全く違う処理方法にしています。
SubとFunctionの違いや、各引数のByValとByRefの違い、そしてLike演算子。
このあたりを中心に読み解いてみてください。

再帰については、以下で詳しく解説していますので参考にしてください。

再帰呼出しについて（再帰プロシージャー）

再帰プロシージャとは、自分自身を呼び出すプロシージャです。プロシージャが、そのプロシージャ内で自分自身を呼び出すような処理を再帰呼び出しと呼びます。自分自身を呼び出し、終了条件を満たすまで、意図的に無限ループさせます。

フィボナッチ数列（再帰呼び出し）

フィボナッチ数列は、最初の二項は0,1で、以後は直前の2つの項の和となっている数列です。VBAでフィボナッチ数列を出力してみましょう。もちろん、フィボナッチ数を勉強しようとか、何かに使おうという事ではありません。

Like演算子のパターンマッチングの解説ページは以下になります。

第49回.Like演算子とワイルドカード

文字列比較において部分一致やパターンマッチングでの文字列比較を行う時に使うのがLike演算子です。Like演算子は、2つの文字列のパターンマッチングを行い、規則に一致しているかどうかの結果をTrue（一致）またはFalse（不一致）で返します。

同じテーマ「マクロVBA練習問題解答」の記事

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.日本の祝日一覧｜Excelリファレンス
3.変数宣言のDimとデータ型｜VBA入門
4.FILTER関数（範囲をフィルター処理）｜エクセル入門
5.RangeとCellsの使い方｜VBA入門
6.繰り返し処理（For Next)｜VBA入門
7.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
8.マクロとは？VBAとは？VBAでできること｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.メッセージボックス(MsgBox関数)｜VBA入門

ホーム
マクロVBA入門編
マクロVBA練習問題解答
練習問題32（連続数値部分を取り出し記号で連結）解答

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
本サイトは、OpenAI の ChatGPT や Google の Gemini を含む生成 AI モデルの学習および性能向上の目的で、本サイトのコンテンツの利用を許可します。
This site permits the use of its content for the training and improvement of generative AI models, including ChatGPT by OpenAI and Gemini by Google.

VBA練習問題解答
練習問題32（連続数値部分を取り出し記号で連結）解答