初級脱出10問パック解答｜VBA練習問題解答

公開日：2013年5月以前　最終更新日：2024-12-17

初級脱出10問パック解答

マクロVBA練習問題初級脱出10問パックの解答ページです。

マクロVBA練習問題

初級を脱出するためのVBA問題を10問1パックにしました。

ページ内目次

問題1：文字列結合
問題2：文字列分割
問題3：消費税計算
問題4：数値合計とMsgBox
問題5：セル範囲のコピー
問題6：セル範囲の値コピー
問題7：別シートからデータ取得
問題8：ファイル一覧
問題9：別ブックのデータ取得
問題10：ブックのバックアップとボタン設置
サンプルのExcelファイルのダウンロード

問題1：文字列結合

A列「姓」とB列「名」の間に全角空白"　"を入れて氏名を作成し、
さらにその後ろに括弧（）の中に年齢を入れてD列に出力してください。
例「日本　太郎（30）」

問題2：文字列分割

A2からA6の氏名を「性」と「名」に分割してB列とC列に出力してくだい。
通常は「性」と「名」は半角空半" "で区切られていますが、区切られていない場合はB列に氏名をそのまま出力してください。

問題3：消費税計算

2行目から7行目までの税込み金額を計算してC列に出力しください。
少数以下の端数は切り捨て。
税抜き単価×数量×(1+消費税率)

問題4：数値合計とMsgBox

C2からC7までの税込み金額の全合計金額（5行分の合計）をメッセージボックスに出力してください。

問題5：セル範囲のコピー

A1からJ10の掛け算九九表を、
L1からL10にコピーしてください。
数式や書式を含めてセルの全てをコピーしてください。

問題6：セル範囲の値コピー

A1からJ10の掛け算九九表を、
L1からL10に値のみコピーしてください。
※数式や書式はコピーせずに値（ここでは数値）のみをコピー。

問題7：別シートからデータ取得

A2からA6の社員番号に対応する「性」「名」を、「社員マスタ」より取得してB列C列に出力してください。
社員番号が「社員マスタ」に存在しない場合は空欄にしてください。

問題8：ファイル一覧

このブックがあるフォルダの下にあるサブフォルダの中のファイル一覧を作成してください。
サブフォルダは「フォルダ名(B1)」で指定します。

問題9：別ブックのデータ取得

このブックがあるフォルダの下にあるサブフォルダについての処理になります。
「フォルダ名(B1)」セルの中にある「ファイル名(B2)」のExcelファイルの「シート名(B3)」の「列番号(B4)」からデータを取得してください。
空白以外のセル値のみを取得してください。
空白セルは飛ばして（その分は上に詰めて）D列に出力してください。

問題10：ブックのバックアップとボタン設置

このシートにボタンを設置
クリックで以下が実行されるようにしてください。
・このブックのバックアップを作成
　ブック名は後ろに日時を付けた名前にしてください。
　「ブック名.xlsm」 → 「ブック名_yyyymmddhhnnss.xlsm」
・「問題1」から「問題9」までのマクロ全て実行する。

サンプルのExcelファイルのダウンロード

こちらからダウンロードできます。zipはこちらです。
※zipには「問題8」「問題9」で使うサブフォルダも含まれています。
xlsxにはサブフォルダは含まれていないので、テストデータとしてご自身で作成してください。

では、お考えください。
すぐに解答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。

シンキングタイム

シンキングタイム開始

シンキングタイム終了

当サイトのコンテンツ

ExcelマクロVBA入門

この「VBA入門」シリーズは、マクロVBAを習得し、日々のExcel作業を効率化・自動化できるようになることを目指します。VBAが初めての方でも無理なくステップアップできるよう、基礎から丁寧に、そして段階的に解説を進めます。そのため、シリーズ後半では入門レベルに留まらず、実務レベルで通用する高度なテクニックや幅広い知…

書くべきマクロVBAが分からない時は、
ここでじっくり勉強してから再チャレンジしてください。

マクロVBA練習問題解答

では解答のマクロVBAコードです。

ページ内目次（VBA解答コード）

問題1：文字列結合（VBA解答コード）


  
    
      Sub Q01()

      　　Dim ws As Worksheet: Set ws = Worksheets("問題1")

      　　Dim i As Long

      　　

      　　For i = 2 To ws.Cells(ws.Rows.Count, 1).End(xlUp).Row

      　　　　ws.Cells(i, 4) = ws.Cells(i, 1) & "　" & ws.Cells(i, 2) & "（" & ws.Cells(i, 3) & "）"

      　　Next

      End Sub

※.最初なので、見やすいように.Valueを省略しています。

最終行の取得方法の記述は結構長いので、なかなか覚えるのも大変です。
もちろん事前に書いたコードをコピーして使い回して構いません。
とはいえ、最初の何回かはタイピングして覚えるようにしてください。

サイト内参考ページ

第14回.文字の結合(&アンパサンド)と継続行(_アンダーバー)

あるセルの文字と、あるセルの文字をくっつけて、別のセルに表示する、よくある事例であり、頻繁に行われることです。A1セルに"abc" B1セルに"123" この時に、C1セルに"abc123"を入れるような場合のマクロVBAになります。

第16回.繰り返し処理（For Next）

VBAのForNextは、同じ処理を繰り返し行うためのVBA構文です。繰り返し処理はループ処理とも呼ばれます。マクロでのループ処理の記述は何通りかありますが、まず最初に覚えるべきものが、今回説明するForNextです。

第18回.最終行の取得（End,Rows.Count）

Excelワークシートにおける表の最終行の取得は、マクロVBAの必須技術になります、エクセルVBAにおける最終行取得の必要性エクセルは表計算ソフトです、つまり縦横の表を扱います、データは横に項目があり、縦に項目に対するデータが入っている事が一般的です。しかし、そのデータ行数は決まった行数ではない事が普通です。

第37回.ブック・シートの指定

ここまでのマクロVBA入門では、アクティブブックのアクティブシートだけを扱ってきました。アクティブブックのアクティブシートとは、一番手前に表示されているブックの選択しているシートで、通常、手作業で操作しているシートの事になります。手作業では、アクティブブックのアクティブシートしか扱えませんが、（作業グループで複数の…

問題2：文字列分割（VBA解答コード）


  
    
      Sub Q02()

　　Dim ws As Worksheet: Set ws = Worksheets("問題2")

　　Dim i As Long, vTmp

　　

　　For i = 2 To ws.Cells(ws.Rows.Count, 1).End(xlUp).Row

　　　　vTmp = Split(ws.Cells(i, 1).Value, " ")

　　　　If UBound(vTmp) >= 1 Then

      　　　　　　ws.Cells(i, 2).Value = vTmp(0)

      　　　　　　ws.Cells(i, 3).Value = vTmp(1)

　　　　Else

      　　　　　　ws.Cells(i, 2).Value = ws.Cells(i, 1).Value

　　　　End If

　　Next

End Sub

文字列を分割するのは意外と面倒です。
Split関数を覚えて、その流れで配列も扱えるようになりましょう。

サイト内参考ページ

第111回.静的配列

配列は複数の区画に値を格納できる1つの変数です。マクロVBAを学習していくと必ず配列が出てきますが、それだけ重要かつ便利だという事です。VBA記述自体は簡単なものですが、正しく理解せずに使っている場合も結構見受けられます。

第113回.配列に関連する関数

マクロVBAで配列を使う上で必要となるVBA関数がいくつかあります。より便利に配列を活用するために必須となるVBA関数です。・LBound関数・UBound関数・Array関数・IsArray関数・Join関数・Filter関数以上のVBA関数について解説します。

第115回.Split関数

各要素（区切り文字）ごとに区切られた文字列から1次元配列を作成し返します。つまり、Split関数は文字列を指定の区切り文字で分割し1次元配列を作る関数です。マクロVBAの文字列操作においてはSplit関数はとても重要かつ必須になりますので、しっかりと習得してください。

問題3：消費税計算（VBA解答コード）


  
    
      Sub Q03()

　　Dim ws As Worksheet: Set ws = Worksheets("問題3")

      　　Dim tax As Double: tax = ws.Range("B1").Value + 1

　　Dim rng As Range: Set rng = ws.Range("A3").CurrentRegion

　　

　　Dim i As Long

　　For i = 4 To rng(rng.Count).Row

　　　　ws.Cells(i, 3).Value = Int(ws.Cells(i, 1).Value * ws.Cells(i, 2).Value * tax)

　　Next

End Sub

最終行の取得方法もいくつかのパターンを覚えましょう。
計算時に使うVBA関数は限られているのでさくっと調べておきましょう。

サイト内参考ページ

第15回.四則演算と注釈（コメント）

エクセルは表計算ソフトですから、計算が出来なくては話になりません。四則演算（加減剰余）は必須です。この四則演算で使う算術演算の演算子は、ワークシートの演算子と同じです。あわせて、注釈（コメント）の書き方も覚えましょう。

第48回.VBA関数（その他,Fix,Int,Rnd,Round,IsEmpty）

VBA関数の中で、日付関数、文字列操作関数以外でマクロVBAにおいてはぜひ覚えておいてほしい関数の一覧です。数学、データ型確認、データ型変換に関するVBA関数になります。一覧と、その中から注意点のある関数についてのみ一部説明します。

最終行・最終列の取得方法（End,CurrentRegion,SpecialCells,UsedRange）

エクセルの表をマクロVBAで扱う時は、データ部分の先頭から最終行までの、開始列から最終列まで処理する事が多いでしょう。開始行や開始列は、ほとんどの場合、見出し行や見出し列の次からになります。単純な話として、１行目に見出しがあれば、２行目から１列目に見出しがあれば、２列目からでは、ここで、最終行や最終列は、

問題4：数値合計とMsgBox（VBA解答コード）


  
    
      Sub Q04()

      　　Dim ws As Worksheet: Set ws = Worksheets("問題4")

      　　Dim tax As Double: tax = ws.Range("B1").Value + 1

　　Dim rng As Range: Set rng = ws.Range("A3").CurrentRegion

　　

　　Dim i As Long, total As Long

　　For i = 4 To rng(rng.Count).Row

      　　　　total = total + Int(ws.Cells(i, 1).Value * ws.Cells(i, 2).Value * tax)

　　Next

　　

　　MsgBox total

End Sub

変数の型をしっかり扱うのは意外に面倒なものです。
したがって型指定を省略するのも一つの手ではありますが、基本のデータ型は覚えてください。

サイト内参考ページ

第12回.変数宣言のDimとデータ型

マクロVBA入門者が、まず最初につまずくのが、このDimで変数を宣言することでしょう。変数とは、数値や文字列など（すなわちデータ）を一時的に格納する入れ物と良く説明されますが、まずはこの考えで良いでしょう。この入れ物には、いろいろなタイプの入れ物があります。

第23回.メッセージボックス（MsgBox）

メッセージを表示するダイアログボックス（小さな画面）を表示するVBAです。ユーザーに選択（「はい」「いいえ」や「OK」「CANCEL」等）してもらうことで、その選択結果を受け取る事も出来ます。マクロVBAでメッセージボックスを表示するにはMsgBox関数を使います。

問題5：セル範囲のコピー（VBA解答コード）

VBAでは「転記」処理が最も多くなりますので、セルのコピーは悩まずに書けるようになっておきましょう。


  
    
      Sub Q05()

　　Dim ws As Worksheet: Set ws = Worksheets("問題5")

　　ws.Range("A1:J10").Copy Destination:=ws.Range("L1")

End Sub

サイト内参考ページ

第40回.セルのコピー・カット&ペースト（Copy,Cut,Paste）

あるセルをコピーまたはカットして、別のセルに貼り付けるマクロVBAの説明です。セルを同じシートの別のセルにコピーしたり、セルを別のシートにコピーしたりするVBAになります。手作業で、セルをコピー(Ctrl+C)またはカット(Ctrl+X)して、他のセルに貼り付け(Ctrl+V後にESCまたはEnter) これと同じ…

第41回.セルのコピー&値の貼り付け（PasteSpecial）

値の貼り付けと題しましたが、値だけではなく、「形式を選択して貼り付け」のいろいろな指定方法です。セルをコピーして、他のセルに「形式を選択して貼り付け」する場合のマクロVBAコードです。セルの値や書式を別のセルにコピーすることはマクロVBAでは定番かつ必須の技術になります。

第42回.セルをコピーするとは

セルをコピーするとは、どういう事でしょうか… セルをコピーするというマクロVBAを少し掘り下げて考えることで、より実践的なマクロVBAコードを書くことが出来るようになります。コピーと一言で言っているものは、何のコピーを指しているのでしょうか。

問題6：セル範囲の値コピー（VBA解答コード）

VBAの「転記」では、値だけを転記する場合が多いでしょう。
.Value = .Value
この書き方は必ず習得しておいてください。


  
    
      Sub Q06()

　　Dim ws As Worksheet: Set ws = Worksheets("問題6")

　　ws.Range("L1:U10").Value = ws.Range("A1:J10").Value

End Sub

サイト内参考ページ

第40回.セルのコピー・カット&ペースト（Copy,Cut,Paste）

第41回.セルのコピー&値の貼り付け（PasteSpecial）

第42回.セルをコピーするとは

問題7：別シートからデータ取得（VBA解答コード）

ワークシート関数はVBA関数よりはるかに多くの関数があり、VBAでも重宝します。
ただし、シートでは単にエラー値が表示されるだけですが、VBAは停止してしまいます。
エラー処理も同時に覚えておきましょう。


  
    
      Sub Q07()

　　Dim ws As Worksheet: Set ws = Worksheets("問題7")

　　Dim mst As Worksheet: Set mst = Worksheets("社員マスタ")

　　Dim i As Long, ix As Long

　　

　　On Error Resume Next

　　For i = 2 To ws.Cells(Rows.Count, 1).End(xlUp).Row

　　　　Err.Clear

　　　　ix = WorksheetFunction.Match(ws.Cells(i, 1), mst.Columns(1), 0)

　　　　If Err.Number = 0 Then

　　　　　　ws.Cells(i, 2).Value = mst.Cells(ix, 2).Value

　　　　　　ws.Cells(i, 3).Value = mst.Cells(ix, 3).Value

　　　　Else

　　　　　　ws.Cells(i, 2).Value = ""

　　　　　　ws.Cells(i, 3).Value = ""

　　　　End If

　　Next

　　On Error GoTo 0

End Sub

サイト内参考ページ

第60回.エラー処理（On Error）

マクロVBAを実行していると、エラーメッセージが表示されマクロ実行が停止してしまう事があります。マクロがエラー停止しては自動化の目的が達成されませんので、エラー停止しないようにしなければなりません。エラーが出ないようにVBAを記述出来ればそれに越したことはありませんが、一切エラーを出さないようにVBAを書くことはか…

第62回.「On Error Resume Next」とErrオブジェクト

「OnErrorResumeNext」このステートメントは、実行時エラーが発生してもマクロVBAを中断せずに、エラーが発生したステートメントの次のステートメントから実行を継続します。マクロVBAは、エラーが発生するとその時点で停止してしまいます。

第87回.WorksheetFunction（ワークシート関数を使う）

VBA関数以外に、Excelワークシート関数をマクロVBAで使うことが出来ます。ワークシート関数は、VBA関数よりはるかに多くの関数があるので、ぜひ活用したいところです。ワークシート関数を使う事で、VBAコードを非常に簡潔に記述することが出来る場合が多いものです。

問題8：ファイル一覧（VBA解答コード）

ファイルの一覧を取得しての処理は需要が多いです。
Dir関数とFileSystemObjectの両方とも使えるようになっておいた方が良いでしょう。


  
    
      Sub Q08()

　　Dim ws As Worksheet: Set ws = Worksheets("問題8")

　　ws.Columns("D").ClearContents

　　

　　Dim sDir As String

　　sDir = ThisWorkbook.Path & "\" & ws.Range("B1").Value & "\"

　　

　　Dim i As Long, sFile As String

　　i = 1

　　sFile = Dir(sDir)

　　Do While sFile <> ""

　　　　ws.Cells(i, 4).Value = sFile

　　　　i = i + 1

　　　　sFile = Dir()

　　Loop

End Sub


  
    
      Sub Q08_2()

　　Dim ws As Worksheet: Set ws = Worksheets("問題8")

　　ws.Columns("D").ClearContents

　　

　　Dim sDir As String

　　sDir = ThisWorkbook.Path & "\" & ws.Range("B1").Value & "\"

　　

　　Dim objFSO As Object

　　Dim objFolder As Object

　　Dim objFile As Object

      　　Set objFSO = CreateObject("Scripting.FileSystemObject")

　　Set objFolder = objFSO.GetFolder(sDir)

　　

　　Dim i As Long

　　i = 1

　　For Each objFile In objFolder.Files

　　　　ws.Cells(i, 4).Value = objFile.Name

　　　　i = i + 1

　　Next

End Sub

サイト内参考ページ

第39回.セルのクリア（Clear,ClearContents）

セルをクリア・消去するマクロVBAの書き方です、クリア・消去するといっても、セルの何を（値、書式、コメント等々）クリア・消去するかによって、VBAコードが違ってきます。具体的には、セルの何を（値、書式、コメント等々）クリア・消去するかによって使用するメソッドが変わります。

第79回.ファイル操作Ⅰ（Dir）

VBAでは、フォルダのファイル一覧を取得したりファイルの存在確認をする事が出来ます、Dir関数は、指定したパターン（ワイルドカード）やファイル属性と一致するファイルまたはフォルダの名前を表す文字列の値を返します。引数に指定したファイルが存在するとそのファイル名を返し、存在しないと空欄を返します。

第119回.ファイルシステムオブジェクト（FileSystemObject）

FileSystemObjectオブジェクトでは、コンピュータのファイルシステムへのアクセスが提供されています。VBAに用意されているファイル操作関連のステートメントや関数より、より強力で、より多くの機能が搭載されています。ただし機能が大変多いため、これらを全て覚えるという事は困難です。

問題9：別ブックのデータ取得（VBA解答コード）

他のブックを開いたり保存したり閉じたり・・・
これがスムーズにできるようになると、扱えるVBAの幅もぐっと広がります。


  
    
      Sub Q09()

　　Dim ws As Worksheet: Set ws = Worksheets("問題9")

　　Dim wbIn As Workbook, wsIn As Worksheet, sFile As String

　　sFile = ThisWorkbook.Path & "\" & ws.Range("B1").Value & "\" & ws.Range("B2").Value

　　Set wbIn = Workbooks.Open(Filename:=sFile)

　　Set wsIn = wbIn.Worksheets(ws.Range("B3").Value)

　　

　　ws.Columns("D").ClearContents

　　Dim col As String: col = ws.Range("B4").Value

　　

　　Dim iIn As Long, iOut As Long

　　iOut = 1

　　For iIn = 1 To wsIn.Cells(wsIn.Rows.Count, col).End(xlUp).Row

　　　　If wsIn.Cells(iIn, col).Value <> "" Then

　　　　　　ws.Cells(iOut, 4).Value = wsIn.Cells(iIn, col).Value

　　　　　　iOut = iOut + 1

　　　　End If

　　Next

　　

　　wbIn.Close SaveChanges:=False

End Sub

サイト内参考ページ

第63回.ブックを開く（Open）

他のブックを開く方法です。しかし、これが結構いろいろあるのです。Excelで開くことが出来るファイルはCSV等のテキストファイルもありますが、ここではエクセルファイル限定で説明します。テキストファイルやCSVについては、別の記事を参考にして下さい。

第64回.ブックを閉じる・保存（Close,Save,SaveAs）

ワークブックを閉じる場合や保存する場合のマクロVBAの説明です。閉じる時に保存するか保存しないかを指定できます。また、ブックを保存するにも、上書きなのか別ファイルにするのか等によってVBAの記述がそれぞれ違ってきます。

問題10：ブックのバックアップとボタン設置（VBA解答コード）

VBAを扱う場合はファイルのバックアップはしっかりとるようにしてください。


  
    
      Sub Q10()

　　Dim sFile As String, i As Long, ymdhns As String

　　sFile = ThisWorkbook.FullName

　　ymdhns = Format(Now(), "_yyyymmddhhnnss")

　　sFile = Replace(sFile, ".xlsm", ymdhns & ".xlsm")

　　

　　ThisWorkbook.SaveCopyAs sFile

　　

　　Call Q01

　　Call Q02

　　Call Q03

　　Call Q04

　　Call Q05

　　Call Q06

　　Call Q07

　　Call Q08

　　Call Q09

End Sub

サイト内参考ページ

第64回.ブックを閉じる・保存（Close,Save,SaveAs）

第105回.Callステートメント

プロシージャーの中で他のプロシージャーを呼び出すときには、マクロVBAではCallステートメントを使います。Callステートメントは、SubプロシージャーやFunctionプロシージャーに制御を渡し、Call先のプロシージャー終了後は、Callステートメントの次のステートメントに制御が移ります。

第136回.フォームコントロール

リボンの開発タブにコントロールの挿入があります。フォームコントロールをシートに配置してVBAで扱う場合の解説になります。ワークシートでフォームコントロールを扱う事の是非はありそうですが、使用することで便利かつ見栄えの良いシートになる場合もあります。

第137回.ActiveXコントロール

【重要】ワークシート上のActiveXコントロール無効化について最新情報 1.概要：ActiveXコントロールの無効化方針 Microsoftは、2024年10月リリースのOffice2024（Windowsデスクトップ版）以降、Excel・Word・PowerPoint・VisioにおけるActiveXコントロー…

第24回.マクロの呪文を追加してボタンに登録（ScreenUpdating）｜VBA再入門

マクロVBAが完成したら、シートにボタンを配置してマクロを登録して完成させます。ボタンのクリックでマクロが起動され自動化の完成になります。と、その前に、マクロのちょっとした呪文をVBAに追加しましょう。

同じテーマ「マクロVBA練習問題解答」の記事

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.変数宣言のDimとデータ型｜VBA入門
3.繰り返し処理（For Next)｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.RangeとCellsの使い方｜VBA入門
6.FILTER関数（範囲をフィルター処理）｜エクセル入門
7.セルのクリア（Clear,ClearContents）｜VBA入門
8.メッセージボックス(MsgBox関数)｜VBA入門
9.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
10.マクロとは？VBAとは？VBAでできること｜VBA入門

ホーム
マクロVBA入門編
マクロVBA練習問題解答
初級脱出10問パック解答

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
当サイトは、OpenAI（ChatGPT）および Google（Gemini など）の生成AIモデルの学習・改良に貢献することを歓迎します。
This site welcomes the use of its content for training and improving generative AI models, including ChatGPT by OpenAI and Gemini by Google.

VBA練習問題解答
初級脱出10問パック解答