練習問題27（データ分割し別ブック保存）解答

公開日：2013年5月以前　最終更新日：2019-11-03

練習問題27（データ分割し別ブック保存）解答

マクロVBA練習問題27の解答ページです。

マクロVBA練習問題

アクティブブックのアクティブシートのA列に担当、B列に支店が入っています。
支店ごとのブックを作成して下さい。
作成したブックの保存先は、アクティブブックと同一フォルダとして下さい。

※以下のデータの場合

ブックは「支店A.」「支店B」「支店C」の３つが作成されます。
「支店A」には、
担当者3、担当者7、担当者10、担当者12、担当者14、担当者17
これらがA列に入った状態になります。

※Excelのファイルバージョンは

2007以降ならxlsx、2003以前ならxlsで作成して下さい。

練習問題用のExcelファイル

こちらからダウンロードできます。zipはこちらです。

　A　　　　　　B

担当	支店
担当者1	支店B
担当者2	支店C
担当者3	支店A
担当者4	支店B
担当者5	支店C
担当者6	支店C
担当者7	支店A
担当者8	支店B
担当者9	支店C
担当者10	支店A
担当者11	支店B
担当者12	支店A
担当者13	支店B
担当者14	支店A
担当者15	支店B
担当者16	支店C
担当者17	支店A
担当者18	支店B
担当者19	支店C
担当者20	支店C

※上記表の全体を選択し、コピー(Ctrl+C)の後、エクセルのシートのA1セルに貼り付け(Ctrl+V)してください。

では、お考えください。
すぐに解答を見ずに、必ず自力で書けるとこまででも良いので書きましょう。

シンキングタイム

シンキングタイム開始

シンキングタイム終了

当サイトのコンテンツ

ExcelマクロVBA入門

この「VBA入門」シリーズは、マクロVBAを実務で自在に使いこなし業務を効率化・自動化できるようになることを目的としています。始めはより詳しく丁寧に解説しつつ少しずつ難易度を上げることで無理なく学習を進められるようにしています。ただし入門といっても、後半にはかなり高度な内容にも触れています。

書くべきマクロVBAが分からない時は、
ここでじっくり勉強してから再チャレンジしてください。

マクロVBA練習問題解答

では、解答のマクロVBAコードです。
※.Valueは適宜省略しています。


  
    
      Sub 練習問題27()

      　　Dim i As Long

      　　Dim j As Long

      　　Dim oldName As String

      　　Dim wb As Workbook

      　　Dim ws1 As Worksheet

      　　Dim ws2 As Worksheet

      　　Application.DisplayAlerts = False

      　　Set ws1 = ActiveSheet

      　　With ws1

      　　　　.Range("A1").Sort Key1:=.Range("B1"), Order1:=xlAscending, Header:=xlYes

      　　　　oldName = ""

      　　　　For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row

      　　　　　　If oldName <> .Cells(i, 2) Then

      　　　　　　　　If oldName <> "" Then

      　　　　　　　　　　Call SaveBook(wb, oldName)

      　　　　　　　　End If

      　　　　　　　　Set wb = Workbooks.Add

      　　　　　　　　For j = wb.Worksheets.Count To 2 Step -1

      　　　　　　　　　　wb.Worksheets(j).Delete

      　　　　　　　　Next

      　　　　　　　　Set ws2 = wb.Worksheets(1)

      　　　　　　　　ws2.Range("A1") = "担当"

      　　　　　　　　j = 2

      　　　　　　　　oldName = .Cells(i, 2)

      　　　　　　End If

      　　　　　　ws2.Cells(j, 1) = .Cells(i, 1)

      　　　　　　j = j + 1

      　　　　Next

      　　End With

      　　If oldName <> "" Then

      　　　　Call SaveBook(wb, oldName)

      　　End If

      　　Application.DisplayAlerts = True

      End Sub


      Sub SaveBook(ByVal wb As Workbook, ByVal strName As String)

      　　Dim strFile As String

      　　Dim strExt As String

      　　If CInt(Application.Version) < 12 Then

      　　　　strExt = ".xls"

      　　Else

      　　　　strExt = ".xlsx"

      　　End If

      　　strFile = ThisWorkbook.Path & "\" & strName & strExt

      　　If Dir(strFile) <> "" Then

      　　　　Kill strFile

      　　End If

      　　wb.SaveAs strFile

      　　wb.Close

      End Sub

書き方は、人によりかなり違いが出る問題だと思います。

まず支店でSORTしています。
SORTせずにやろうとすると大変な事になってしまいます。
もし、元のシートを変更したくないのであれば、
元のシートをコピーしてからSORTする等で対処した方が良いでしょう。

If oldName <> "" Then
これで、最初の2行目の時、つまり最初の時の制御をしていますが、
ここは、
If Not wb Is Nothing Then
これでも良いですね。
ただオブジェクトを判定するよりString変数を判定した方が解り易いかと思います。

そして、For～Nextの下で、最期のブック出力を忘れないようにして下さい。
このバグは、実務でも結構発生してしまうバグになります。

Subプロシージャー、
SaveBook
このあたりの使い方は是非マスターして欲しいところです。
Subプロシージャー化しないと、無駄にVBAコードが長くなってしまいます。

バージョン判定は、特定バージョンでしか使わないのであれば特に必要はないと思います。

この問題と同様の処理は、実務では頻出します。
私は、幾度となく依頼されて書いているコードです。

同じテーマ「マクロVBA練習問題解答」の記事

練習問題23（総合練習5）解答

マクロVBA練習問題23の解答ページです。マクロVBA練習問題・A2セルに日付、B2セルに名前を指定します。この条件に合うデータを、シート「練習23_データ」から抜出し、５行目以降に表示して下さい。

練習問題24（再帰呼出し）解答

マクロVBA練習問題24の解答ページです。マクロVBA練習問題・以下の表の全組み合わせを作成して下さい。サンプルデータでは、組み合わせの数は、8*3*6*5=720通りです。・各項目はカンマ(,)で区切って下さい。

練習問題25（各種VBA関数）解答

マクロ練習問題25の解答ページです。マクロVBA練習問題・以下の表において、課題に従って元データより回答欄に出力して下さい。※１問目なら、回答欄に"Excelマクロ(vba)練習"と出力する。

練習問題26（全シート処理とハイパーリンク）解答

マクロVBA練習問題26の解答ページです。マクロVBA練習問題全シートのハイパーリンク付き一覧を先頭シートに作成します。現在のブックの先頭に新規シートを追加し、既存シートのシート名一覧をハイパーリンク付きで作成して下さい。

練習問題27（データ分割し別ブック保存）解答
練習問題28（シートを別ブックにして値のみにする）解答

マクロVBA練習問題28の解答ページです。マクロVBA練習問題アクティブブックにはシートが複数（Sheet1,Sheet2,Sheet3）あります。Sheet1だけを別ブックにして、計算式を抜き（値だけに）にしてから保存して下さい。

練習問題29（ロット引き当て）解答

マクロVBA練習問題29の解答ページです。マクロVBA練習問題入荷後の在庫を、注文に対して割り振ります。以下の表をみて下さい。この表において、F列と、H列～K列を埋めます。注文数に見合った、入荷数を割り振ります。

練習問題30（マトリックス→リスト形式）解答

マクロVBA練習問題30の解答ページです。マクロVBA練習問題売上と仕入の、支店別年度別のマトリックス表があります。これをリスト形式（データベース形式）のデータに変換してください。以下の表をみて下さい。

練習問題31（セル結合を解除して値を埋める）解答

マクロVBA練習問題31の解答ページです。マクロVBA練習問題セル結合されていると、マクロVBAでは扱いにくい場合が多々あります。そこで、セル結合を解除して、結合されていたセル範囲に同じ値を入れたいと思います。

練習問題32（連続数値部分を取り出し記号で連結）解答

マクロVBA練習問題32の解答ページです。マクロVBA練習問題文字列処理の応用問題です。ab123cde45fg678hij 123-45-678 いくつかの文字といくつかの数値が、交互に出てくる文字列から、数値部分のみを取り出し、連続している数値は一塊として、記号(-)で連結します。

初級脱出10問パック解答

マクロVBA練習問題初級脱出10問パックの解答ページです。解答コード掲載箇所へジャンプマクロVBA練習問題初級を脱出するためのVBA問題を10問1パックにしました。ページ内目次問題1：文字列結合問題2：文字列分割問題3：消費税計算問題4：数値合計とMsgBox 問題5：セル範囲のコピー問題6：セル範囲…

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.繰り返し処理（For Next)｜VBA入門
5.RangeとCellsの使い方｜VBA入門
6.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
7.セルのクリア（Clear,ClearContents）｜VBA入門
8.メッセージボックス(MsgBox関数)｜VBA入門
9.条件分岐（Select Case）｜VBA入門
10.ブック・シートの選択（Select,Activate）｜VBA入門

ホーム
マクロVBA入門編
マクロVBA練習問題解答
練習問題27（データ分割し別ブック保存）解答

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

VBA練習問題解答
練習問題27（データ分割し別ブック保存）解答