ExcelマクロVBAサンプル集
オセロを作りながらマクロVBAを学ぼう№8

ExcelマクロVBAの実用サンプル、エクセルVBA集と解説
最終更新日:2019-11-10

オセロを作りながらマクロVBAを学ぼう№8


ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第8回です。


前回までで大分ゲームらしくなってきました。
そろそろ、PC対戦の機能を入れたいところですが、
今回は、はPC対戦の機能を入れる前に、気になる細かい部分を変更しておきます。

追加・変更する機能は、
・石を置ける場所の色を変更するかどうかを選択できるようにする
・対戦途中で、「対戦開始」をクリックすると、いきなり初期配置になってしまうので、
 メッセージを出して確認するようにする。
・相手の石を自分の石に取り替える処理が速すぎて、ひっくり返している感じがないので、
 少しゆっくり石を取り換えて、アニメーションっぽくする。


シートの変更
シート保護の解除と、スクロールエリアの解除をしてください。

マクロVBA画像

「置ける場所の色を変える」のチェックボックスを追加してください。

マクロVBA画像

適当にドラッグして配置してください。

右クリックからプロパティで、
(オブジェクト名)

「chk置ける場所」
として下さい。



シートモジュール
「置ける場所の色を変える」のチェックボックスをクリックした時のイベントプロシージャーを挿入します。

以下を、シートモジュールに追加してください。
デザインモードで、チェックボックスをダブルクリックすると、空のイベントプロシージャーが作成されます。



Private Sub chk置ける場所_Click()
  If TargetSheet Is Nothing Then
    Exit Sub
  End If
  Unprotect
  If chk置ける場所.Value Then
    Call 置ける場所表示
  Else
    Range("盤面").Interior.Color = Range("ベース色").Interior.Color
  End If
  Protect
End Sub

チェックが付けられたときは、「置ける場所表示」をCallします。
チェックが外されたときは、盤面全体を初期色に設定します。



APIを使用する
Sleep(一定時間停止する)のAPIを使うために、標準モジュールの先頭にDeclareを追加します。

Option Explicit

Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Public TargetSheet As Worksheet
Public 置く石 As Range
Public 相手石 As Range

使う時は、
Sleep 200
ミリ秒で指定します。



対戦開始
以下の赤太字部分を追加してください。



Sub 対戦開始()
  With TargetSheet
    If WorksheetFunction.CountA(.Range("盤面")) > 4 Then
      If MsgBox("対局途中です。" & vbLf & vbLf & _
            "新規対局を開始してもよろしいですか?", _
            vbYesNo, "確認") = vbNo Then
        Exit Sub
      End If
    End If
    .Range("先番石").Copy Destination:=.Range("手番石")
    .Range("手番石").Offset(, 1) = "の番です。"
    .Range("盤面").ClearContents
    Call 共通変数設定
    Call 石を置く(.Range("盤面").Cells(4, 4), 置く石)
    Call 石を置く(.Range("盤面").Cells(5, 5), 置く石)
    Call 石を置く(.Range("盤面").Cells(4, 5), 相手石)
    Call 石を置く(.Range("盤面").Cells(5, 4), 相手石)
    Call 置ける場所表示
  End With
End Sub

WorksheetFunction.CountAで置かれている石の数を取得し、
4より多ければ確認メッセージを表示して確認しています。



置ける場所表示

以下の赤太字部分を追加してください。

Sub 置ける場所表示()
  Dim myRng As Range
  With TargetSheet
    If Not Sheet1.chk置ける場所.Value Then
      Exit Sub
    End If
    .Range("盤面").Interior.Color = .Range("ベース色").Interior.Color
    For Each myRng In .Range("盤面")
      If is置ける全方向(myRng, True) Then
        myRng.Interior.Color = .Range("置ける場所色").Interior.Color
      End If
    Next
  End With
End Sub

chk置ける場所のチェックがついていない時は、Subプロシージャーを抜けています。



石を置くときの処理 ・・・ is置ける1方向

以下の赤太字部分が変更箇所です。

Function is置ける1方向(ByVal Target As Range, _
      ByVal i As Long, _
      ByVal j As Long, _
      ByVal isTry As Boolean) As Boolean
  Dim r As Long
  Dim c As Long
  Dim is置く石 As Boolean
  Dim is相手石 As Boolean
  Dim myRng As Range
  Dim myRng2 As Range
  '石を置くセルの行列位置
  r = Target.Row
  c = Target.Column
  Set myRng = Nothing
  With TargetSheet
    '空白or置く石と同じ石が出てくるまで判定
    Do
      r = r + i
      c = c + j
      '空白(石が置かれていない
      If .Cells(r, c) = "" Then
        Exit Do
      End If
      '自分の石が置かれている
      If .Cells(r, c).Font.Color = 置く石.Font.Color Then
        is置く石 = True
        Exit Do
      End If
      '相手の石が置かれている
      If .Cells(r, c).Font.Color <> 置く石.Font.Color Then
        is相手石 = True
        If myRng Is Nothing Then
          Set myRng = .Cells(r, c)
        Else
          Set myRng = Union(myRng, .Cells(r, c))
        End If
      End If
    Loop
  End With
  '自分の石が置かれていて終了した時、それまでに相手の石があるか
  If is置く石 = True And is相手石 = True Then
    is置ける1方向 = True
    If Not isTry Then
      Call 石を置く(Target, 置く石)
      Sleep 200
      For Each myRng2 In myRng
        Sleep 100
        Call 石を置く(myRng2, 置く石)
      Next
    End If
  End If
End Function

手番の石を置いた後、200ミリ秒待ちます。
相手の石を取り換える時は、まとめてではなく、一つずつ取り替えます。
そしてその都度、100ミリ秒待ちます。

待ち時間のミリ秒は適当に設定しています。
長すぎると遅く感じるし、短すぎると効果が分からなくなっしまいます。



さて、これでPC対戦の準備が出来ました。
いよいよ、次回からは、PC対戦を実現します。
まずは強さは考えずに、
とにかくPCが自動で打つ機能を実現していきます。


№9へ続きます。
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第9回です。前回までで人が打つのであれば不自由のない機能が実装できたと思います。さて、ここからはPC対戦の機能を入れていきます。

全体の目次
はじめに
ExcelマクロVBAでオセロ(リバーシ)を作っていきながら、マクロVBAを学んで行きましょう。目的は、マクロVBAの学習であり、思考を整理しVBAでプログラミングする学習です。従って、強いソフトを作ることが目的ではありませんので、最近流行のAIなんちゃら…なんていうのは考えるつもりはありません。
№1.シートの用意と標準モジュールの挿入
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第1回です。まずはシートを用意しなければなりません、このシートの作り方で、その後の手間が随分と変わってきますので、しっかりと作ります。とはいえ、まずは一般的な感じで作ってみます、今後必要に応じて追加・変更していきます。
№2.ブックを開いたときの処理と初期配置
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第2回です。前回でシートの準備と標準モジュールを挿入しましたので、今回からは、マクロVBAをどんどん書き足していきます。まずは、イベントプロシージャーを作っていきます。
№3.自分の石を置ける場所の判定の整理
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第3回です。いよいよ自分の石を置いて、相手の石をひっくり返す処理に進むのですが、その前に、そもそも自分の石を置ける場所はどこなのか…。クリックしたセルは、自分の石を置いて良いセルなのかの判定が必要です。
№4.自分の石を置ける場所の判定の実装
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第4回です。石を置ける場所の定義を、前回は文章で書きました、今回は、それをもとにマクロVBAのプログラミングをしていきます。考え方は決定しているので、後はVBAに翻訳(コーディング)していくだけです。
№5.シート機能を拡張して今後の準備
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第5回です。前回で石を置ける場所の判定が完成しましたので、これからは、ゲームとしての機能を一つずつ追加していきます。まずは、石を置ける場所の色を変更してわかりやすくしてみます。
№6.黒石白石を交互に打って相手の石をひっくり返す
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第6回です。いよいよ今回は、黒石白石を交互に打てるようにします。もちろん、相手の石を挟んでいる場所は、自分の石に取り替えます。
№7.パス確認、終局確認、石数取得
VBAでオセロ(リバーシ)を作っていきながらVBAを学ぶ第7回です。前回までで、黒石白石を交互に打つことができるようになりましたが、まだまた不都合な点があります。石を打つ場所がない時に、パスが出来ないから先に進まない… 全部石が埋まっても、何も変化がない… そもそも、どっちが勝っているのかもわからない… つまり、
№8.石を置ける場所の表示とアニメーション
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第8回です。前回までで大分ゲームらしくなってきました。そろそろ、PC対戦の機能を入れたいところですが、今回は、はPC対戦の機能を入れる前に、気になる細かい部分を変更しておきます。
№9.PC対戦の実装
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第9回です。前回までで人が打つのであれば不自由のない機能が実装できたと思います。さて、ここからはPC対戦の機能を入れていきます。
№10.置く場所に重みを付けて少しだけ強く
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第10回です。前回は、PCが自動で打つ機能を実装しました。強さはともかく、とにかくPCが勝手に売ってくれるようになりました。
№11.相手の応手を評価してさらに強く
VBAでオセロ(リバーシ)を作っていきながらVBAを学ぶ第11回です。前回の石を置く場所に重みを付けることで、超々初心者なら勝てるかもしれないというレベルにはなりました。ですが、ある程度オセロをやった事のある人なら、まあ負けることはないでしょう 今回は、自分の打つ場所ではなく、
№12.PC対PCの対戦で強さを確認
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第12回です。前回は、相手の応手を判定して、自分の置く場所を決められるようにしました。オセロソフトとしては、そこそこの強さになりました。
№13.パラメーターと重みを調整してさらに強く
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第12回です。前回は、PC1からPC5までの5段階の状態で、総当り対戦で強さを判定しましたが、PC5が最も強い事が確認出来ました。それでもPC5では、まだまだ、ある程度オセロをやった事のある人には勝てないレベルです。
№14.やはり「待った」が欲しい
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第14回です。前回で、6段階の強さのPCオセロが完成しました、一番強いPC6でも、まだまだそれほどの強さとは言えませんが、初心者の人なら苦戦するでしょうし、私も油断すれば負けてしまうくらいの強さにはなっています。
№15.棋譜で対局を再現
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第15回です。棋譜が扱えるようになり、「待った」の実装も出来ました。棋譜が扱えるようになったので、今回は、対局を再現できるようにします。
№16.これまでを振り返りつつ全体のまとめ
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第16回です。15回に渡って、オセロ作成をしてきました、マクロVBAコードはかなりの量になっています。今回は最終回として、これまでを振り返ってみます。


ここまでのサンプルファイルのダウンロード




新着記事NEW ・・・新着記事一覧を見る

VBAでのCSVの扱い方まとめ|VBAサンプル集(11月9日)
VBAにおける変数のメモリアドレスについて|VBA技術解説(11月8日)
空文字列の扱い方と処理速度について(""とvbNullString)|VBA技術解説(1月7日)
Errオブジェクトとユーザー定義エラー|VBA入門(11月5日)
シングルクォートの削除とコピー(PrefixCharacter)|VBA技術解説(11月4日)
ユーザー定義型の制限とクラスとの使い分け|VBA技術解説(11月3日)
クリップボードに2次元配列を作成してシートに貼り付ける|VBA技術解説(11月1日)
VBAクラスを使ったイベント作成(Event,RaiseEvent,WithEvents)|VBA技術解説(10月31日)
VBAクラスのAttributeについて(既定メンバーとFor Each)|VBA技術解説(10月19日)
VBAの用語について:ステートメントとは|VBA技術解説(10月16日)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.RangeとCellsの使い方|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
5.変数宣言のDimとデータ型|ExcelマクロVBA入門
6.繰り返し処理(For Next)|ExcelマクロVBA入門
7.マクロって何?VBAって何?|ExcelマクロVBA入門
8.ひらがな⇔カタカナの変換|エクセル基本操作
9.空白セルを正しく判定する方法(IsEmpty,IsError,HasFormula)|VBA技術解説
10.セルに文字を入れるとは(Range,Value)|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。




    このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
    本文下部へ