ExcelマクロVBAサンプル集
オセロを作りながらマクロVBAを学ぼう№12

ExcelマクロVBAの実用サンプル、エクセルVBA集と解説
最終更新日:2017-12-06

オセロを作りながらマクロVBAを学ぼう№12


ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第12回です。


前回は、相手の応手を判定して、自分の置く場所を決められるようにしました。
オセロソフトとしては、そこそこの強さになりました。

今回は、
PC対PCを何十回と対戦させる機能を実装して、
実際に、どの程度強さに違いがあるのかを検証します。
もちろん、結果の記録も必要になります。

追加・変更する機能

・PCの種類分のリーグマッチ(総当り戦、先後両方を戦う)にする。
・終了メッセージを表示しない。
 PC対PCの場合は、パスのメッセージは既に表示していません。
・1試合が終わってもマクロを終了させない。
・対戦結果を記録する。


PCの種類分のリーグマッチ(総当り戦、先後両方を戦う)にする。
PC1~PC5で、先後入れ替えての総当り戦にします。



Sub 対戦シミュレーション()
  Dim i1 As Long
  Dim i2 As Long
  Dim i3 As Long
  Dim ary
  Sheet1.Unprotect
  Set TargetSheet = Sheet1
  StopMsg = True
  ary = Array("PC1", "PC2", "PC3", "PC4", "PC5")
  With Worksheets("対戦履歴")
    .Range("A1").CurrentRegion.Offset(1).ClearContents
    For i1 = 0 To 4
      For i2 = 0 To 4
        If ary(i1) <> ary(i2) Then
          Sheet1.cmb1.Text = ary(i1)
          Sheet1.cmb2.Text = ary(i2)
          For i3 = 1 To 100
            DoEvents
            Application.Calculation = xlCalculationManual
            Call 対戦開始
            Call 対戦履歴追加
            DoEvents
            Application.Calculation = xlCalculationAutomatic
          Next
        End If
      Next
    Next
  End With
  Sheet1.Protect
  MsgBox "終了"
End Sub

ary = Array("PC1", "PC2", "PC3", "PC4", "PC5")
Array関数を使って、1行で済ませています。
Array関数は、配列が格納されたバリアント型(Variant)の値を返します。Array関数 Array(arglist) arglist 必ず指定します。引数arglistには、値のリストをカンマ(,)で区切って指定します。

For i1 = 0 To 4
  For i2 = 0 To 4
    If ary(i1) <> ary(i2) Then
これで総当り、かつ、同じPCは対戦しないようにしています。

For i3 = 1 To 100
この100が同じ組み合わせで戦う試合数になります。



終了メッセージを表示しない。
メッセージ抑止に使う、モジュールレベルのPublic変数を追加。
StopMsgがTrueの場合は、メッセージを出さないようにします。

Option Explicit

Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Public TargetSheet As Worksheet
Public 置く石 As Range
Public 相手石 As Range
Public isPCvsPC As Boolean
Public StopMsg As Boolean

Sub 対戦開始()
  With TargetSheet
    If Not StopMsg Then
      If WorksheetFunction.CountA(.Range("盤面")) > 4 Then
        If MsgBox("対局途中です。" & vbLf & vbLf & _
              "新規対局を開始してもよろしいですか?", _
              vbYesNo, "確認") = vbNo Then
          Exit Sub
        End If
      End If
    End If
    If Sheet1.cmb1.Text Like "PC*" And Sheet1.cmb2.Text Like "PC*" Then
      isPCvsPC = True
    Else
      isPCvsPC = False
    End If
    .Range("先番石").Copy Destination:=.Range("手番石")
    .Range("手番石").Offset(, 1) = "の番です。"
    .Range("盤面").ClearContents
    Call 共通変数設定
    Call 石を置く(.Range("盤面").Cells(4, 5), 置く石)
    Call 石を置く(.Range("盤面").Cells(5, 4), 置く石)
    Call 石を置く(.Range("盤面").Cells(4, 4), 相手石)
    Call 石を置く(.Range("盤面").Cells(5, 5), 相手石)
    Call 置ける場所表示
    If isPC Then
      Call 次手着手(次手候補)
    End If
  End With
End Sub



Sub 終局処理()
  If StopMsg Then Exit Sub
  With TargetSheet
    Select Case True
      Case .Range("先番石").Offset(, 2).Value > .Range("後番石").Offset(, 2).Value
        MsgBox "終局" & vbLf & vbLf & "●先手番「" & Sheet1.cmb1.Text & "」の勝ちです。"
      Case .Range("先番石").Offset(, 2).Value < .Range("後番石").Offset(, 2).Value
        MsgBox "終局" & vbLf & vbLf & "○後手番「" & Sheet1.cmb2.Text & "」の勝ちです。"
      Case Else
        MsgBox "終局" & vbLf & vbLf & "引き分けです。"
    End Select
    .Range("手番石").Clear
    .Range("手番石").Offset(, 1).ClearContents
  End With
End Sub

赤太字の部分が追加された場所です。



1試合が終わってもマクロを終了させない。

今までは、終局の時、
End
これで、マクロそのものを終了させていましたが、
対戦を続けるために、マクロは終了しないようにします。

Function 終局確認() As Boolean
  Dim myRng As Range
  Dim isPass As Boolean
  With TargetSheet
    If WorksheetFunction.CountA(.Range("盤面")) = 64 Then
      Call 終局処理
      終局確認 = True
      Exit Function
    End If
    isPass = True
    For Each myRng In .Range("盤面")
      If is置ける全方向(myRng, True) Then
        isPass = False
      End If
    Next
    If isPass = True Then
      isPass = True
      Set 置く石 = 相手石
      For Each myRng In .Range("盤面")
        If is置ける全方向(myRng, True) Then
          isPass = False
        End If
      Next
      If isPass = True Then
        Call 終局処理
        終局確認 = True
        Exit Function
      End If
    End If
  End With
  Call 共通変数設定
End Function

Sub 次手着手(ByVal Target As Range)
  Dim myRng As Range
  Call 共通変数設定
  If is置ける全方向(Target, False) Then
    Call 手番交代
    Call 置ける場所表示
    If 終局確認 Then Exit Sub
    Call パス確認
    If isPC Then
      If Not isPCvsPC Then
        Sleep 400
      End If
      Call 次手着手(次手候補)
    End If
  End If
End Sub

赤太字の部分が追加された場所です。

終局確認をFunctionにして、終局の時にTrueを返すようにします。
次手着手で、終局確認がTrueなら、Exit Subすることで、マクロを継続させています。



対戦結果を記録する。
対戦結果を出力するシートを用意します。
シート「対戦結果」を作ります。

マクロVBA画像

A列からE列に結果を出力します。

マクロVBA画像

PC6はまだ作成していませんが、
次回には作成する予定なので、シートには前もって入れておきました。

G列からN列には、A列からE列の結果を集計する関数を入れます。
I3セルには、
=COUNTIFS($A:$A,$G3,$B:$B,I$2,$E:$E,"黒")
I4セルには、
=COUNTIFS($A:$A,$G4,$B:$B,I$2,$E:$E,"白")
G4セルは空白に見えますが、「PC1」が入っています。
表示形式のユーザー定義で、「;;;」として、表示を消しています。
表示形式のユーザー定義は、
正の数の書式;負の数の書式;ゼロの書式;文字列の書式
つまり、正:負;ゼロ;文字、全て省略しているので、何も表示されないことになります。
他のPC部分には、コピペで数式を設定できます。

下の集計部分は、簡単に全体が分かるように、
上部の結果を=でとってきているだけです。


Sub 対戦履歴追加()
  Dim j As Long
  With Worksheets("対戦履歴")
    j = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
    .Cells(j, 1) = Sheet1.cmb1.Text
    .Cells(j, 2) = Sheet1.cmb2.Text
    .Cells(j, 3) = Sheet1.Range("先番石").Offset(, 2)
    .Cells(j, 4) = Sheet1.Range("後番石").Offset(, 2)
    If .Cells(j, 3) > .Cells(j, 4) Then
      .Cells(j, 5) = "黒"
    End If
    If .Cells(j, 3) < .Cells(j, 4) Then
      .Cells(j, 5) = "白"
    End If
  End With
End Sub

シート「対戦履歴」にの最終行の次の行に出力しています。
勝敗については、シート「オセロ」にあるので、
シートのオブジェクト名である、Sheet1を使って取得くしています。
オブジェクト名を使う理由としては、
cmb1やcmb2の値を取得するコード記述が簡単になることです。
マクロVBA画像
このように、インテリセンスも効きます。



実際に戦わせた結果
100戦ずつ戦わせた結果です。

VBAマクロ画像

左が先手、上が後手
上段が先手勝ち、下段が後手勝ちです。

予定通りではありますが、
PC1から順に強くなっています。
というか、そのように評価値のポイントを調整した結果ではあります。
偶然の要素もあるので、細かい数値の違いはともかくとして、
全体的に先手が優位な状況にあるようです。
これは一般的に、オセロに置いて先手が優位という事ではなく、
今回のソフトのロジック特有のものだと思います。



今回の実装での強さレベルを判定することが出来ました。
強さを判定できるという事は、
いろいろなパターンで作成していく上で、
対戦させることでより強いソフトになっているかどうかを判定できるという事です。

次回は、もう少し、打つ手を工夫するようにして、
さらに強くしていこうと思います。
少なくとも、PC5に完全に勝ち越せるPC6を作ろうと思います。


№13へ続きます。
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第12回です。前回は、PC1からPC5までの5段階の状態で、総当り対戦で強さを判定しましたが、PC5が最も強い事が確認出来ました。それでもPC5では、まだまだ、ある程度オセロをやった事のある人には勝てないレベルです。

全体の目次
はじめに
ExcelマクロVBAでオセロ(リバーシ)を作っていきながら、マクロVBAを学んで行きましょう。目的は、マクロVBAの学習であり、思考を整理しVBAでプログラミングする学習です。従って、強いソフトを作ることが目的ではありませんので、最近流行のAIなんちゃら…なんていうのは考えるつもりはありません。
№1.シートの用意と標準モジュールの挿入
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第1回です。まずはシートを用意しなければなりません、このシートの作り方で、その後の手間が随分と変わってきますので、しっかりと作ります。とはいえ、まずは一般的な感じで作ってみます、今後必要に応じて追加・変更していきます。
№2.ブックを開いたときの処理と初期配置
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第2回です。前回でシートの準備と標準モジュールを挿入しましたので、今回からは、マクロVBAをどんどん書き足していきます。まずは、イベントプロシージャーを作っていきます。
№3.自分の石を置ける場所の判定の整理
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第3回です。いよいよ自分の石を置いて、相手の石をひっくり返す処理に進むのですが、その前に、そもそも自分の石を置ける場所はどこなのか…。クリックしたセルは、自分の石を置いて良いセルなのかの判定が必要です。
№4.自分の石を置ける場所の判定の実装
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第4回です。石を置ける場所の定義を、前回は文章で書きました、今回は、それをもとにマクロVBAのプログラミングをしていきます。考え方は決定しているので、後はVBAに翻訳(コーディング)していくだけです。
№5.シート機能を拡張して今後の準備
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第5回です。前回で石を置ける場所の判定が完成しましたので、これからは、ゲームとしての機能を一つずつ追加していきます。まずは、石を置ける場所の色を変更してわかりやすくしてみます。
№6.黒石白石を交互に打って相手の石をひっくり返す
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第6回です。いよいよ今回は、黒石白石を交互に打てるようにします。もちろん、相手の石を挟んでいる場所は、自分の石に取り替えます。
№7.パス確認、終局確認、石数取得
VBAでオセロ(リバーシ)を作っていきながらVBAを学ぶ第7回です。前回までで、黒石白石を交互に打つことができるようになりましたが、まだまた不都合な点があります。石を打つ場所がない時に、パスが出来ないから先に進まない… 全部石が埋まっても、何も変化がない… そもそも、どっちが勝っているのかもわからない… つまり、
№8.石を置ける場所の表示とアニメーション
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第8回です。前回までで大分ゲームらしくなってきました。そろそろ、PC対戦の機能を入れたいところですが、今回は、はPC対戦の機能を入れる前に、気になる細かい部分を変更しておきます。
№9.PC対戦の実装
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第9回です。前回までで人が打つのであれば不自由のない機能が実装できたと思います。さて、ここからはPC対戦の機能を入れていきます。
№10.置く場所に重みを付けて少しだけ強く
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第10回です。前回は、PCが自動で打つ機能を実装しました。強さはともかく、とにかくPCが勝手に売ってくれるようになりました。
№11.相手の応手を評価してさらに強く
VBAでオセロ(リバーシ)を作っていきながらVBAを学ぶ第11回です。前回の石を置く場所に重みを付けることで、超々初心者なら勝てるかもしれないというレベルにはなりました。ですが、ある程度オセロをやった事のある人なら、まあ負けることはないでしょう 今回は、自分の打つ場所ではなく、
№12.PC対PCの対戦で強さを確認
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第12回です。前回は、相手の応手を判定して、自分の置く場所を決められるようにしました。オセロソフトとしては、そこそこの強さになりました。
№13.パラメーターと重みを調整してさらに強く
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第12回です。前回は、PC1からPC5までの5段階の状態で、総当り対戦で強さを判定しましたが、PC5が最も強い事が確認出来ました。それでもPC5では、まだまだ、ある程度オセロをやった事のある人には勝てないレベルです。
№14.やはり「待った」が欲しい
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第14回です。前回で、6段階の強さのPCオセロが完成しました、一番強いPC6でも、まだまだそれほどの強さとは言えませんが、初心者の人なら苦戦するでしょうし、私も油断すれば負けてしまうくらいの強さにはなっています。
№15.棋譜で対局を再現
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第15回です。棋譜が扱えるようになり、「待った」の実装も出来ました。棋譜が扱えるようになったので、今回は、対局を再現できるようにします。
№16.これまでを振り返りつつ全体のまとめ
ExcelマクロVBAでオセロ(リバーシ)を作っていきながらマクロVBAを学ぶ第16回です。15回に渡って、オセロ作成をしてきました、マクロVBAコードはかなりの量になっています。今回は最終回として、これまでを振り返ってみます。


ここまでのサンプルファイルのダウンロード




新着記事NEW ・・・新着記事一覧を見る

VBAでのCSVの扱い方まとめ|VBAサンプル集(11月9日)
VBAにおける変数のメモリアドレスについて|VBA技術解説(11月8日)
空文字列の扱い方と処理速度について(""とvbNullString)|VBA技術解説(1月7日)
Errオブジェクトとユーザー定義エラー|VBA入門(11月5日)
シングルクォートの削除とコピー(PrefixCharacter)|VBA技術解説(11月4日)
ユーザー定義型の制限とクラスとの使い分け|VBA技術解説(11月3日)
クリップボードに2次元配列を作成してシートに貼り付ける|VBA技術解説(11月1日)
VBAクラスを使ったイベント作成(Event,RaiseEvent,WithEvents)|VBA技術解説(10月31日)
VBAクラスのAttributeについて(既定メンバーとFor Each)|VBA技術解説(10月19日)
VBAの用語について:ステートメントとは|VBA技術解説(10月16日)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.RangeとCellsの使い方|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
5.変数宣言のDimとデータ型|ExcelマクロVBA入門
6.繰り返し処理(For Next)|ExcelマクロVBA入門
7.マクロって何?VBAって何?|ExcelマクロVBA入門
8.ひらがな⇔カタカナの変換|エクセル基本操作
9.空白セルを正しく判定する方法(IsEmpty,IsError,HasFormula)|VBA技術解説
10.セルに文字を入れるとは(Range,Value)|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。




    このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
    本文下部へ