VBA100本ノック 65本目：固定長テキスト出力

最終更新日：2021-02-22

VBA100本ノック 65本目：固定長テキスト出力

フォーマット（左詰め文字、右詰め数値）に従い、固定長テキストを出力する問題です。

ツイッター連動企画です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。

VBAテスト用のサンプルデータは、VBA100本ノックの目次ページ からもダウンロードできます。

マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。

出題

#VBA100本ノック 65本目
固定長データの出力です。
「フォーマット」シートに従い、2行目以降をテキスト出力してください。
文字形態は、N:右詰め0埋め、C:左詰め半角スペース埋め。
項目間区切りなしで連続で出力
※シートは任意
※本題ではないので出力ファイル及び文字コードは任意

サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_65.xlsm
https://excel-ubara.com/vba100sample/VBA100_65.zip

VBA作成タイム

この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。

他の人の回答および解説を見て、書いたVBAを見直してみましょう。

頂いた回答

出題ツイートの引用ツイートでの回答

解説

全銀に模したデータサンプルにしましたが、最近は固定長の必要性は少なくなりましたね。
でも全く不要という事もないので、一度は経験しておいた方が良いだろうという事で出題しました。
DictionaryとFileSystemObjectを参照設定して使っています。


  
    
      Sub VBA100_65_01()

　　Dim ws As Worksheet, rng As Range

　　Dim objFso As New FileSystemObject

　　Dim objTS As TextStream, sFile As String

　　

　　Set ws = ActiveSheet

　　Set rng = ws.Range("A1").CurrentRegion

　　sFile = ws.Parent.Path & "\data.txt"

　　Set objTS = objFso.CreateTextFile(sFile, True)

　　

      　　Dim dic As Dictionary, i As Long, j As Long, ary

　　Set dic = getFormat(Worksheets("フォーマット"))

　　For i = 2 To rng.Rows.Count

　　　　ReDim ary(rng.Columns.Count)

　　　　For j = 1 To rng.Columns.Count

　　　　　　ary(j) = getFixedString(dic, rng(1, j).Value, rng(i, j).Value)

　　　　Next

　　　　objTS.WriteLine Join(ary, "")

　　Next

　　objTS.Close

　　

　　Set dic = Nothing: Set objTS = Nothing: Set objFso = Nothing

　　ThisWorkbook.FollowHyperlink sFile

End Sub


Function getFormat(ByVal ws As Worksheet) As Dictionary

　　Dim dic As New Dictionary, i As Long

　　For i = 2 To ws.Cells(ws.Rows.Count, 1).End(xlUp).Row

　　　　dic(ws.Cells(i, 1).Value) = Array(ws.Cells(i, 2).Value, ws.Cells(i, 3).Value)

　　Next

　　Set getFormat = dic

End Function


Function getFixedString(ByVal dic As Object, ByVal aFormat, ByVal aIn) As String

　　If Not dic.Exists(aFormat) Then Exit Function '未登録列は空で返しスキップ

　　Dim sForm As String: sForm = dic(aFormat)(0)

　　Dim iLen As Integer: iLen = dic(aFormat)(1)

　　If UCase(sForm) = "N" Then

　　　　getFixedString = Right(String(iLen, "0") & aIn, iLen)

　　Else

　　　　getFixedString = Left(aIn & Space(iLen), iLen)

　　End If

End Function

Dictionaryを使ったので、全体としては少し長くなってしまいました。
処理最後で作成したテキストをメモ帳（既定なら）で開いています。
補足はありません。

補足

補足はありません。

サイト内関連ページ

第116回．ファイル操作Ⅱ（OpenとClose）

・Openステートメント・Closeステートメント・OpenステートメントとCloseステートメントの使用例

第117回．ファイル操作Ⅱ（Line Input #）

・Line Input # ステートメント・EOF関数・Line Input # ステートメントと EOF関数の使用例．

第118回．ファイル操作Ⅱ（Print #）

VBAでファイル（CSV等）を扱う時は、最初に、ファイルを開き、その後に、読込み書込みを行い、最後に、ファイルを閉じます。ファイルを書き込む時には、Print#ステートメントを使います。Print#ステートメントシーケンシャル出力モード(OutputまたはAppend)で開いたファイルにデータを書き込むファイル入…

第119回．ファイルシステムオブジェクト（FileSystemObject）

・FileSystemObjectオブジェクトの使用方法・FileSystemObjectオブジェクトのプロパティとメソッド・FileSystemObjectオブジェクトのメソッドの戻り値・FileSystemObjectオブジェクトの使用例・FileSystemObjectオブジェクトの関連記事と実践例

VBAでファイルを既定のアプリで開く方法｜VBA技術解説

・実行テストメイン・Shell関数・batファイル（コマンドプロンプト）・WScript.Shell ・Shell.Application ・FollowHyperlink ・最後に

同じテーマ「VBA100本ノック」の記事

62本目：独自のZLOOKUP関数を作成
 63本目：複数シートの連結
 64本目：リンクされた図（カメラ機能）
65本目：固定長テキスト出力
66本目：全サブフォルダからファイルを探す
 67本目：ComboBoxとListBox
68本目：全テキストボックスの転記
 69本目：ダブルクリックでセル結合を解除
 70本目：ステータスバーに1秒ごとに時刻が表示
 71本目：パワーポイントへグラフを貼り付け
 72本目：ITをDXに変換（文字列操作）

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.RangeとCellsの使い方｜VBA入門
3.繰り返し処理（For Next)｜VBA入門
4.変数宣言のDimとデータ型｜VBA入門
5.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
6.マクロとは？VBAとは？VBAでできること｜VBA入門
7.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
8.並べ替え（Sort）｜VBA入門
9.Range以外の指定方法（Cells,Rows,Columns）｜VBA入門
10.条件分岐（IF）｜VBA入門

ホーム
マクロVBA入門編
VBA100本ノック
65本目：固定長テキスト出力

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

VBA練習問題
VBA100本ノック 65本目：固定長テキスト出力