VBA100本ノック 13本目：文字列の部分フォント

公開日：2020-10-31　最終更新日：2021-02-22

VBA100本ノック 13本目：文字列の部分フォント

セルに入っている文字列の一部のフォントを変更する問題です。

ツイッター連動企画です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。

VBAテスト用のサンプルデータは、VBA100本ノックの目次ページ からもダウンロードできます。

マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。

出題

#VBA100本ノック 13本目
選択セル（Selection:複数範囲あり）の文字列に「注意」という文字があった場合は、その「注意」の文字だけを"赤の太字"に設定してください。
セル以外（図形等）が選択されている場合は何もせずに正常終了するようにしてください。

サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_13.xlsm
https://excel-ubara.com/vba100sample/VBA100_13.zip

VBA作成タイム

この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。

他の人の回答および解説を見て、書いたVBAを見直してみましょう。

頂いた回答

出題ツイートの引用ツイートでの回答

解説

Selectionは必ずしもセルとは限らず図形等の場合もあるのでTypeNameでセル選択か確認しています。
また、計算式の場合は一部のFont変更はできないのでHasFormulaで外しています。
範囲が大きいと処理時間がかかるので1列全体を上限にしました。
文字列内の一部のFont設定はCharactersで設定します。


  
    
      Sub VBA100_13_01()

      　　If TypeName(Selection) <> "Range" Then

　　　　Exit Sub

　　End If

　　If Selection.CountLarge > Rows.Count Then

　　　　MsgBox "選択範囲が大きすぎます。"

　　　　Exit Sub

　　End If

　　

　　Const cns注意 = "注意"

　　Dim rng As Range

　　Dim ix As Long

　　

　　For Each rng In Selection

　　　　If Not rng.HasFormula Then

　　　　　　ix = 1

　　　　　　Do

　　　　　　　　ix = InStr(ix, rng.Value, cns注意)

　　　　　　　　If ix = 0 Then Exit Do

      　　　　　　　　With rng.Characters(ix, Len(cns注意))

　　　　　　　　　　.Font.Bold = True

　　　　　　　　　　.Font.Color = vbRed

　　　　　　　　End With

　　　　　　　　ix = ix + Len(cns注意)

　　　　　　Loop

　　　　End If

　　Next

End Sub

先のVBAではInstrの開始位置をずらしながら"注意"を探しましたが、1文字ずつ確認していく方法もあります。
よほど大量に処理するのでなければどちらでも良いと思います。
ですが、いずれにしても選択範囲が大きい場合（全セル選択）にこれでは対応できません。


  
    
      　　Const cns注意 = "注意"

　　Dim rng As Range

　　Dim i As Long

　　

　　For Each rng In Selection

      　　　　If Not rng.HasFormula Then

　　　　　　For i = 1 To Len(rng.Value) - Len(cns注意) + 1

　　　　　　　　If Mid(rng.Value, i, Len(cns注意)) = cns注意 Then

　　　　　　　　　　With rng.Characters(i, Len(cns注意))

　　　　　　　　　　　　.Font.Bold = True

　　　　　　　　　　　　.Font.Color = vbRed

　　　　　　　　　　End With

　　　　　　　　End If

　　　　　　Next

　　　　End If

　　Next

解決方法としてSpecialCellsを使う方法が回答されています。
https://twitter.com/ExcelQBag/status/1322447866233675780
https://twitter.com/furyutei/status/1322492458496782336
このVBAサンプルは記事補足に載せておきました。

補足

複数列全体や全セル選択時に、For EachでSelectionを処理したのでは、膨大な時間がかかってしまいます。
処理対象は文字列が入っているセルだけです。
そこで、
SpecialCells(xlCellTypeConstants, xlTextValues)
これで、文字列の入っているセルだけに絞っています。
1セルしか選択していない場合は、SpecialCellsは全セル対象になってしまうので、Intersectで本来の選択範囲にしています。

また参考として、正規表現を使って文字列を検索する方法を紹介しておきます。


  
    
      Sub VBA100_13_03()

　　Dim target As Range

　　On Error Resume Next

　　Set target = Intersect(Selection, Selection.SpecialCells(xlCellTypeConstants, xlTextValues))

　　If target Is Nothing Then Exit Sub

　　

　　Const cns注意 = "注意"

　　

　　Dim reg As Object

　　Set reg = CreateObject("VBScript.RegExp")

　　

　　Dim rng As Range

　　For Each rng In target

　　　　Call CharactersFont(rng, cns注意, reg)

　　Next

　　

　　Set reg = Nothing

End Sub


Sub CharactersFont(rng As Range, argStr As String, reg As Object)

　　Dim mc As Object

　　Dim m As Object

　　

　　With reg

　　　　.Pattern = argStr

　　　　.Global = True

　　　　Set mc = .Execute(rng.Value)

　　End With

　　

　　For Each m In mc

　　　　With rng.Characters(m.FirstIndex + 1, m.Length)

　　　　　　.Font.Bold = True

　　　　　　.Font.Color = vbRed

　　　　End With

　　Next

End Sub

サイト内関連ページ

第16回．繰り返し処理（For Next）｜VBA入門

・For Next ステートメント・For Next 例文・For Next をステップイン実行で目で見て確認しましょう。・１行置きに処理する場合・Exit For ・For～Nextのネスト（入れ子）・最後に一言

第17回．繰り返し処理（Do Loop）｜VBA入門

・Do～Loopの構文・条件式・Do Loop 例文・Exit Do ・Do～Loopのネスト（入れ子）・最後に一言

第47回．VBA関数（文字列操作,Replace,InStr,StrConv）｜VBA入門

・文字列操作に関するVBA関数の一覧・Replace関数・InStr関数・StrConv関数・最後に

第135回．ジャンプの選択オプション（SpecialCells）｜VBA入門

・ジャンプの選択オプションとは・RangeオブジェクトのSpecialCellsメソッド・SpecialCellsの使用例

VBAで正規表現を利用する（RegExp）｜VBA技術解説

・VBScript 廃止に向けて、VBA プロジェクトを対応させる方法・メタ文字・正規表現・正規表現RegExpの使い方・RegExpオブジェクト・RegExpの使用例・RegExp関連のオブジェクト・Execute（Matches,Match,SubMatches）の使用例・Replaceの使用例・先読み：肯定先読み、否定先読み・正規表現の実践例

同じテーマ「VBA100本ノック」の記事

10本目：行の削除
 11本目：セル結合の警告
 12本目：セル結合を解除
13本目：文字列の部分フォント
14本目：社外秘シート削除
 15本目：シートの並べ替え
 16本目：無駄な改行を削除
 17本目：重複削除（ユニーク化）
18本目：名前定義の削除
 19本目：図形のコピー
 20本目：ブックのバックアップ

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.日本の祝日一覧｜Excelリファレンス
3.変数宣言のDimとデータ型｜VBA入門
4.FILTER関数（範囲をフィルター処理）｜エクセル入門
5.RangeとCellsの使い方｜VBA入門
6.繰り返し処理（For Next)｜VBA入門
7.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
8.マクロとは？VBAとは？VBAでできること｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.メッセージボックス(MsgBox関数)｜VBA入門

ホーム
マクロVBA入門編
VBA100本ノック
13本目：文字列の部分フォント

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
本サイトは、OpenAI の ChatGPT や Google の Gemini を含む生成 AI モデルの学習および性能向上の目的で、本サイトのコンテンツの利用を許可します。
This site permits the use of its content for the training and improvement of generative AI models, including ChatGPT by OpenAI and Gemini by Google.

VBA練習問題
VBA100本ノック 13本目：文字列の部分フォント