VBA100本ノック 18本目：名前定義の削除
名前定義を削除する問題です。
名前定義から、非表示なっているものを表示し、参照不可になっている名前定義は削除します。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
出題
不明な名前定義が沢山あるので、以下の処理をしてください。
・非表示の名前定義は表示にする
・参照範囲に「#REF!」が含まれる場合は削除しイミディエイトに「名前」と「参照範囲」を出力
・最後に非表示件数と削除件数をメッセージボックスに表示
※ブック指定は任意
https://excel-ubara.com/vba100sample/VBA100_18.xlsm
https://excel-ubara.com/vba100sample/VBA100_18.zip
VBA作成タイム
この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。
他の人の回答および解説を見て、書いたVBAを見直してみましょう。
頂いた回答
解説
参照範囲の数式は、RefersToやRefersToLocal、またValueでも取得できます。
この式に"#REF!"が含まれている場合に名前定義を削除しています。
Sub VBA100_18_01()
Dim visibleCnt As Long
Dim deleteCnt As Long
Dim nm As Name
For Each nm In ActiveWorkbook.Names
If Not nm.Visible Then
visibleCnt = visibleCnt + 1
nm.Visible = True
End If
If InStr(nm.RefersTo, "#REF!") > 0 Then
deleteCnt = deleteCnt + 1
Debug.Print nm.Name & ":" & nm.RefersTo
nm.Delete
End If
Next
MsgBox "非表示件数：" & visibleCnt & vbLf & _
"削除件数：" & deleteCnt
End Sub
VBAで削除できなくても、ダイアログでは大抵の場合削除できるはずなので、手動で削除してください。
エラー対応したVBAは記事補足に記載しました。
補足
フィルター等のエクセル機能で自動作成されるものはVBAでは削除できないものが多くあります。
（ただし普通は、不要になった時点でエクセルが名前定義を削除します。）
また、古いExcelのバージョンで作成したファイルを使い回したものには、今の名前定義で許可されない名前が入っていたりします。
簡単に作成できる別のエラー「#NAME?」で削除エラーを再現しました。
参照範囲=#NAME?
この名前定義はVBAで削除できません。
これについては、特に削除しなければならないものではありませんが、
VBAでDeleteがエラーになるサンプルとして使いました。
エラーの原因については、メッセージの通りですが
そもそも規則に反する名前が入っていることが問題な気もしますが・・・
とにかく、VBAがエラーになってしまうので、これに対応したVBAが以下になります。
Sub VBA100_18_02()
Dim visibleCnt As Long
Dim deleteCnt As Long
Dim errorCnt As Long
Dim nm As Name
On Error Resume Next
For Each nm In ActiveWorkbook.Names
If Not nm.Visible Then
visibleCnt = visibleCnt + 1
nm.Visible = True
End If
If InStr(nm.RefersTo, "#REF!") > 0 Or _
InStr(nm.RefersTo, "#NAME?") > 0 Then
deleteCnt = deleteCnt + 1
Debug.Print nm.Name & ":" & nm.RefersTo
Err.Clear
nm.Delete
If Err Then
errorCnt = errorCnt + 1
Debug.Print "↑「削除失敗」手動削除願います。"
End If
End If
Next
MsgBox "非表示件数：" & visibleCnt & vbLf & _
"削除件数 ：" & deleteCnt & vbLf & _
"内削除失敗：" & errorCnt
End Sub
InStr(nm.RefersTo, "#REF!") > 0
これは、Likeで書く場合は「#」がワイルドカードになるので、以下のように書く必要があります。
If nm.RefersTo Like "*[#]REF!*"
サイト内関連ページ
同じテーマ「VBA100本ノック」の記事
15本目：シートの並べ替え
16本目：無駄な改行を削除
17本目：重複削除（ユニーク化）
18本目：名前定義の削除
19本目：図形のコピー
20本目：ブックのバックアップ
21本目：バックアップファイルの削除
22本目：FizzBuzz発展問題
23本目：シート構成の一致確認
24本目：全角英数のみ半角
25本目：マトリックス表をDB形式に変換
新着記事NEW ・・・新着記事一覧を見る
AIは便利なはずなのに…「AI疲れ」が次の社会問題になる｜生成AI活用研究(2026-02-16)
カンマ区切りデータの行展開｜エクセル練習問題(2026-01-28)
開いている「Excel/Word/PowerPoint」ファイルのパスを調べる方法｜エクセル雑感(2026-01-27)
IMPORTCSV関数（CSVファイルのインポート）｜エクセル入門(2026-01-19)
IMPORTTEXT関数（テキストファイルのインポート）｜エクセル入門(2026-01-19)
料金表（マトリックス）から金額で商品を特定する｜エクセル練習問題(2026-01-14)
「緩衝材」としてのVBAとRPA｜その終焉とAIの台頭｜エクセル雑感(2026-01-13)
シンギュラリティ前夜：AIは機械語へ回帰するのか｜生成AI活用研究(2026-01-08)
電卓とプログラムと私｜エクセル雑感(2025-12-30)
VLOOKUP/XLOOKUPが異常なほど遅くなる危険なアンチパターン｜エクセル関数応用(2025-12-25)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.日本の祝日一覧｜Excelリファレンス
3.変数宣言のDimとデータ型｜VBA入門
4.FILTER関数（範囲をフィルター処理）｜エクセル入門
5.RangeとCellsの使い方｜VBA入門
6.繰り返し処理（For Next)｜VBA入門
7.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
8.マクロとは？VBAとは？VBAでできること｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.メッセージボックス(MsgBox関数)｜VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 18本目：名前定義の削除
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
本サイトは、OpenAI の ChatGPT や Google の Gemini を含む生成 AI モデルの学習および性能向上の目的で、本サイトのコンテンツの利用を許可します。
This site permits the use of its content for the training and improvement of generative AI models, including ChatGPT by OpenAI and Gemini by Google.