VBA100本ノック 52本目：複数シートの一括印刷
複数シートの印刷を印刷キューに1ジョブで登録する問題です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
出題
シート名に「印刷」という文字を含むシートを全て印刷したい。
ただし途中で他の人の印刷が紛れ込まないように、印刷キューには1ジョブで登録したい。
VBAは確認のためプレビューで記述、つまり、1回のプレビューで複数シートを出力してください。
※ブックは任意
頂いた回答
解説
ただし、非表示シートが含まれているとエラーになってしまうので、含めないようにしてください。
印刷プレビューには、PrintPreviewメソッドまたはPrintOutメソッドにPreview:=Trueを指定します。
Sub VBA100_52_01()
Dim wb As Workbook: Set wb = ActiveWorkbook
Dim sht As Object
Dim ary() As String
Dim cnt As Long
For Each sht In wb.Sheets
If sht.Name Like "*印刷*" Then
If sht.Visible = xlSheetVisible Then
ReDim Preserve ary(cnt)
ary(cnt) = sht.Name
cnt = cnt + 1
End If
End If
Next
If cnt > 0 Then
wb.Sheets(ary).PrintOut preview:=True
End If
End Sub
選択シートを追加していき、SelectedSheetsを印刷する方法もあります。
Selectはあまり使いたくはありませんが、このような方法もあるにはあります。
これは記事補足に掲載しました。
補足
省略値はTrueです。
Trueを指定した場合は、選択範囲を置き換えます。
Falseを指定した場合は、選択範囲を拡張します。
Sub VBA100_52_02()
Dim wb As Workbook: Set wb = ActiveWorkbook
Dim sht As Object
Dim selSht As Object
Dim cnt As Long
wb.Activate
Set selSht = ActiveWindow.SelectedSheets
For Each sht In wb.Sheets
If sht.Name Like "*印刷*" Then
If sht.Visible = xlSheetVisible Then
If cnt = 0 Then
sht.Select
Else
sht.Select Replace:=False
End If
cnt = cnt + 1
End If
End If
Next
If cnt > 0 Then
ActiveWindow.SelectedSheets.PrintOut preview:=True
selSht.Select
End If
End Sub
サイト内関連ページ
同じテーマ「VBA100本ノック」の記事
49本目：条件付き書式の判定
50本目：トリボナッチ数列
51本目：シート一覧と印刷ページ数
52本目：複数シートの一括印刷
53本目：テーブルの扱いと年齢計算
54本目：シートのChangeイベント
55本目：他ブックのマクロを起動
56本目：数式内の自身のシート名を消す
57本目：ファイルの更新日時
58本目：番号リストを簡潔にした文字列で返す
59本目：12ヶ月分のシートを四半期で分割
新着記事NEW ・・・新着記事一覧を見る
PropertyのSetはLetでも良い｜VBA技術解説(2021-03-31)
エクセル麻雀ミニゲーム｜VBAサンプル集(2021-03-09)
VBA100本ノック 100本目：WEBから100本ノックのリストを取得｜VBA練習問題(2021-03-03)
VBA100本ノック 魔球編：2桁の最小公倍数｜VBA練習問題(2021-02-02)
Select Caseでの短絡評価（ショートサーキット）の使い方｜VBA技術解説(2021-01-03)
VBA100本ノック 迷宮編：巡回セル問題｜VBA練習問題(2020-12-31)
VBA100本ノック 魔球編：閉領域の塗り潰し｜VBA練習問題(2020-12-16)
VBA100本ノック 魔球編：組み合わせ問題｜VBA練習問題(2020-12-02)
将棋とプログラミングについて～そこには型がある～｜エクセル雑感(2020-11-22)
VBA100本ノック 1本目：セルのコピー｜VBA練習問題(2020-10-19)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.RangeとCellsの使い方｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.マクロって何？VBAって何？｜VBA入門
5.Excelショートカットキー一覧｜Excelリファレンス
6.繰り返し処理（For Next)｜VBA入門
7.Range以外の指定方法（Cells,Rows,Columns）｜VBA入門
8.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
9.セルに文字を入れるとは（Range,Value）｜VBA入門
10.とにかく書いてみよう（Sub,End Sub）｜VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 52本目：複数シートの一括印刷
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。