VBA100本ノック 48本目：配列と数値型

公開日：2020-12-16　最終更新日：2021-01-13

VBA100本ノック 48本目：配列と数値型

配列内の数値型のみ整数部に切り捨てる問題です。
配列は1次元と2次元だけに対応します。

ツイッター連動企画です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。

VBAテスト用のサンプルデータはご自身でご用意ください。

出題

#VBA100本ノック 48本目
引数が1次元または2次元配列の場合、以下の処理を行いVariantで返すFunctionを作成。
xxx (v as Variant) As Variant
・数値型は整数部のみにする(1.5→1, -1.5→-1)
・数値型以外(文字列、日付、その他)はそのまま
※配列以外と3次元配列以上もそのまま返してください。

VBA作成タイム

この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。

他の人の回答および解説を見て、書いたVBAを見直してみましょう。

頂いた回答

出題ツイートの引用ツイートでの回答

解説

配列の次元数の確認はVBAに機能がありません。
UBoundでエラーになる手前が次元数として判断するのが一般的です。
変数のデータ型を判定するには、
TypeNameまたはVarTypeを使います。


  
    
      Function VBA100_48_01(v As Variant) As Variant

　　Dim rtn: rtn = v

　　

　　Dim i As Long, j As Long

　　Select Case getDimension(rtn)

　　　　Case 1

　　　　　　For i = LBound(rtn) To UBound(rtn)

　　　　　　　　If numVar(rtn(i)) Then rtn(i) = Fix(rtn(i))

　　　　　　Next

　　　　Case 2

　　　　　　For i = LBound(rtn, 1) To UBound(rtn, 1)

　　　　　　　　For j = LBound(rtn, 2) To UBound(rtn, 2)

　　　　　　　　　　If numVar(rtn(i, j)) Then rtn(i, j) = Fix(rtn(i, j))

　　　　　　　　Next

　　　　　　Next

　　End Select

　　VBA100_48_01 = rtn

End Function


Function numVar(v As Variant) As Boolean

　　numVar = False

　　Select Case TypeName(v)

　　　　Case "Single", "Double", "Currency", "Decimal"

　　　　　　numVar = True

      　　End Select

'　　Select Case VarType(v)

'　　　　Case vbSingle, vbDouble, vbCurrency, vbDecimal

'　　　　　　numVar = True

'　　End Select

End Function


Function getDimension(v As Variant) As Integer

　　Dim tDim As Integer

　　On Error Resume Next

　　Do While Err.Number = 0

　　　　getDimension = getDimension + 1

　　　　tDim = UBound(v, getDimension)

　　Loop

　　getDimension = getDimension - 1

End Function

今回は、
配列の次元数、Variantとデータ型についての理解を深める問題でした。
補足はありません。
記事にはVBAを掲載しました。

補足

補足はありません。

サイト内関連ページ

第12回．変数宣言のDimとデータ型｜VBA入門

・データ型・変数の使い方・変数名の規則・良く使われる変数名・自動型変換、暗黙の型変換・変数宣言の必要性・Dim変数宣言のまとめ

第106回．Functionプロシージャー｜VBA入門

プログラム（マクロVBA）内で特定の処理を実行し値を返すプロシージャーです。これはつまり、Functionプロシージャーで独自の関数をつくれるということです。Subプロシージャーとの違いは、値を返すか返さないかの違いです。

第107回．プロシージャーの引数｜VBA入門

・引数の構文・引数の使用例・引数について

第111回．静的配列｜VBA入門

・配列とは・静的配列と動的配列・配列の宣言・多次元配列・要素の下限の変更・配列について

第112回．動的配列（ReDim）｜VBA入門

・ReDimステートメント・要素数の変更について・配列について

TypeName関数｜VBA関数

TypeName関数は、引数で指定された変数に関する情報を文字列で返します。TypeName関数 TypeName(varname) varname 必ず指定します。ユーザー定義型の変数を除く、任意のバリアント型(Variant)の変数を指定します。

VarType関数｜VBA関数

VarType関数は、引数に指定された変数の内部処理形式を表す整数型(Integer)の値を返します。VarType関数 VarType(varname) varname 必ず指定します。引数varnameには、ユーザー定義型の変数を除く、任意のバリアント型(Variant)の変数を指定します。

同じテーマ「VBA100本ノック」の記事

45本目：テーブルに列追加
 46本目：名前定義に使える文字
 47本目：Window操作
48本目：配列と数値型
49本目：条件付き書式の判定
 50本目：トリボナッチ数列
 51本目：シート一覧と印刷ページ数
 52本目：複数シートの一括印刷
 53本目：テーブルの扱いと年齢計算
 54本目：シートのChangeイベント
 55本目：他ブックのマクロを起動

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.日本の祝日一覧｜Excelリファレンス
3.変数宣言のDimとデータ型｜VBA入門
4.FILTER関数（範囲をフィルター処理）｜エクセル入門
5.RangeとCellsの使い方｜VBA入門
6.繰り返し処理（For Next)｜VBA入門
7.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
8.マクロとは？VBAとは？VBAでできること｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.メッセージボックス(MsgBox関数)｜VBA入門

ホーム
マクロVBA入門編
VBA100本ノック
48本目：配列と数値型

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
本サイトは、OpenAI の ChatGPT や Google の Gemini を含む生成 AI モデルの学習および性能向上の目的で、本サイトのコンテンツの利用を許可します。
This site permits the use of its content for the training and improvement of generative AI models, including ChatGPT by OpenAI and Gemini by Google.

VBA練習問題
VBA100本ノック 48本目：配列と数値型