入力規則のリスト入力の妥当性判定
入力規則のリスト入力は、Excelの機能の中でも頻繁に使われる機能です。
コピペで値の貼り付けを行うと、どんな値でも入力出来てしまいます。
結果として想定外の値が入力されてしまう事がある以上、入力値のチェックは必要になってきます。
以下は、入力規則を設定したセル値が正しい値かどうかを判定する方法になります。
入力規則に反するデータかの判定Function
Function isValidationOk(ByVal rng As Range) As Boolean
If rng.Validation.Value Then
isValidationOk = True
Else
isValidationOk = False
End If
End Function
入力規則に反しているかどうかだけであれば、これだけで判定できます。
.Validation.Value
Falseなら入力規則に反したデータ
Function isValidationOk(ByVal rng As Range) As Boolean
isValidationOk = rng.Validation.Value
End Function
これだけで良いものです。
そもそもこれではFunction関数にする意味もないので、説明的に書いたものです。
もうこの部分だけのFunctionでは意味がないので、
シート全体として入力規則に反していないかを判定するFunctionにしてみましょう。
Function isValidaionOk(ByVal ws As Worksheet) As Boolean
Dim valiRng As Range
Dim myRng As Range
On Error Resume Next
Set valiRng = ws.Cells.SpecialCells(xlCellTypeAllValidation)
If Err Then Exit Function
On Error GoTo 0
For Each myRng In valiRng
If Not myRng.Validation.Value Then
isValidaionOk = False
Exit Function
End If
Next
isValidaionOk = True
End Function
入力規則がまったく無いシートの場合、SpecialCellsがエラーになってしまいます。
そこで、On Error Resume Nextでエラー判定を行っています。
入力規則のリスト入力の妥当性を判定Function
しかし、単に判定するだけなら上記VBAで良いという事で追記しました。
ただし、タイトルにある通りリスト入力限定です。
全部の入力規則に自力で対応するのはかなり大変です。
Function isValidationOk(ByRef argRange As Range) As Boolean
Dim myRange As Range
Dim strList As String
On Error Resume Next
isValidationOk = True
'空欄はOKとする
If argRange.Value = "" Then Exit Function
'入力規則のリストかどうか
If argRange.Validation.Type = xlValidateList Then
'入力規則がない場合はエラーが発生するので
If Err.Number > 0 Then Exit Function
Else
'入力規則のリスト以外はチェックしない
Exit Function
End If
If Left(argRange.Validation.Formula1, 1) = "=" Then
'リストがセル範囲指定の場合
Set myRange = Application.Range(Mid(argRange.Validation.Formula1, 2))
If WorksheetFunction.CountIf(myRange, argRange) > 0 Then
Exit Function
End If
Else
'リストデータが直接指定の場合
strList = "," & argRange.Validation.Formula1 & ","
If strList Like "*," & argRange.Value & ",*" Then
Exit Function
End If
End If
'入力規則のリストにないのでエラー
isValidationOk = False
End Function
入力規則において、直接リストデータを入れている場合は、
.Validation.Formula1には、"A,B,C,・・・"とカンマ区切りの文字列が入っています。
そこで、前後に,カンマを付け足して、",文字列,"でLike判定しています。
他のセル範囲を参照している場合は、"="に続けてセル範囲のアドレスが入っています。
他のシートならシート修飾が付いていて、同一シートならセルアドレスだけが取得されます。
そこでこの=の後ろの文字列からセル範囲を取得し、
そのセル範囲に対して、シートのCountIf関数で判定しています。
最後に
それは、使用者に対する注意事項として伝えるへきものです。
しかし、
万一コピペ等でリスト以外のデータが入力されてしまった場合に、その後の処理に支障をきたすのであれば、やはりチェックしておく必要出てきます。
そのような場合があれば、参考にして下さい。
同じテーマ「マクロVBAサンプル集」の記事
右クリックメニューの変更（CommandBars）
エクセルのアイコン取得（FaceID）
素数を求めるマクロ
入力規則のリスト入力の妥当性判定
配色を使用したカラー設定を固定カラーに変更
指定セルに名前定義されているか判定する
Excel2003(xls)を2007以降(xlsx,xlsm)に変換する（HasVBProject）
ハイパーリンクからファイルのフルパスを取得する
ボタンに表示されているテキストを取得（Application.Caller）
Excelの表をPowerPointへ図として貼り付け
VBAで表やグラフをPowerPointへ貼り付ける
新着記事NEW ・・・新着記事一覧を見る
シンギュラリティ前夜：AIは機械語へ回帰するのか｜生成AI活用研究(2026-01-08)
電卓とプログラムと私｜エクセル雑感(2025-12-30)
VLOOKUP/XLOOKUPが異常なほど遅くなる危険なアンチパターン｜エクセル関数応用(2025-12-25)
2段階の入力規則リスト作成：最新関数対応｜エクセル関数応用(2025-12-24)
IFS関数をVBAで入力するとスピルに関係なく「@」が付く現象について｜VBA技術解説(2025-12-23)
数値を記号の積み上げでグラフ化する（■は10、□は1）｜エクセル練習問題(2025-12-09)
AI時代におけるVBAシステム開発に関する提言｜生成AI活用研究(2025-12-08)
GrokでVBAを作成：条件付書式を退避回復するVBA｜エクセル雑感(2025-12-06)
顧客ごとの時系列データから直前の履歴を取得する｜エクセル雑感(2025-11-28)
ちょっと悩むVBA厳選問題｜エクセル雑感(2025-11-28)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.日本の祝日一覧｜Excelリファレンス
3.変数宣言のDimとデータ型｜VBA入門
4.FILTER関数（範囲をフィルター処理）｜エクセル入門
5.RangeとCellsの使い方｜VBA入門
6.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
7.繰り返し処理（For Next)｜VBA入門
8.セルのクリア（Clear,ClearContents）｜VBA入門
9.マクロとは？VBAとは？VBAでできること｜VBA入門
10.条件分岐（Select Case）｜VBA入門
- ホーム
- マクロVBA応用編
- マクロVBAサンプル集
- 入力規則のリスト入力の妥当性判定
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
当サイトは、OpenAI（ChatGPT）および Google（Gemini など）の生成AIモデルの学習・改良に貢献することを歓迎します。
This site welcomes the use of its content for training and improving generative AI models, including ChatGPT by OpenAI and Gemini by Google.