MOS VBAエキスパート対策 | ユーザーフォームとメニューの操作 | MOS Excel VBAエキスパート対策です



最終更新日:2018-03-16

ユーザーフォームとメニューの操作


・ユーザーフォームの操作
・コントロールの操作
・メニューとツールバーの操作


【ここでのポイント】

ユーザーフォーム、コントロールについては、学ぶべきことが膨大にあります。
ユーザーフォーム・コントロールのそれぞれのプロパティ・イベントを知らなければVBAが書けないからです。

公式テキストでも、最も多くのページを割いています。

しかし、
実務では、VBEの画面にプロパィ一覧は表示されますし、入力候補も表示されますので、
例えば、スペルまでは覚えておく必要がありません。
ところが、MOS試験ではそう言う訳にはいかない為、ある程度は暗記しておく必要があります。

ただし、
試験に出されるプロパティ・イベントは限られているので、
公式テキストと本ページに書いてあるプロパティ・イベントを優先して覚えておけば良いでしょう。


ユーザーフォームの操作
コントロールの操作

以下で紹介している、ユーザーフォーム入門は、
画面サンプルを載せて自習できるようにしていますので、読みながら実際にやってみて下さい。

全部覚えようとしても大変なので、以下の点を意識しながら読んでください。

フォーム
UserForm.Show [vbModal | vbModeless]
Unload Me

Initializeイベント
QueryCloseイベント


コントロール
代表的なプロパティ
  Caption Value Text ListIndex ListCount List
コマンドボタン          
ラベル          
テキストボックス        
コンボボックス  
リストボックス  
チェックボックス        
オプションボタン        

ValueとTextは同じ値になります。
特段の使い分けはありません。

コンボボックスとリストボックスのListIndexは、
0から始まります。
未選択時は-1になります。

試験問題に出されたときに難しいのは、
コンボボックスとリストボックスになるでしょう。
この二つは、重点的に覚えて下さい。

代表的なメソッド
コンボボックスとリストボックスの
AddItemメソッド

代表的なイベント
Clickイベント
これは、全てのコントロールにありますが、
コマンドボタンでの使用がほとんどです。

実務では、
チェックボックスとオプションボタンで使いますが、試験には出る可能性は低いでしょう。

ユーザーフォーム入門
第1回.ユーザーフォームを挿入
第2回.フォームのプロパティ
第3回.コントロールの追加(コマンドボタン)
第4回.コントロールの位置・サイズ調整
第5回.ラベルの追加
第6回.テキストボックス(TextBox)の追加
第7回.テキストボックス(TextBox)の値をセルへ
第8回.セルの値をテキストボックスへ
第9回.標準モジュールとフォーム間のデータ受け渡しT
第10回.標準モジュールとフォーム間のデータ受け渡しU
第11回.コンボボックス(ComboBox)の追加
第12回.リストボックス(ListBox)の追加
第13回.チェックボックス(CheckBox)の追加
第14回.オプションボタン(OptionButton)の追加
第15回.ここまでの整理
第16回.アクティブコントロールに色を付ける
第17回.Enterキーで次のコントロールに移動する
第18回.2段階コンボボックス
第19回.テキストボックス数値編集
第20回.テキストボックスの各種イベント
第21回.ユーザーフォームの各種イベント

上記のユーザーフォーム入門では、
最初の方は、初めてユーザーフォームを使う入門者を想定して、かなり詳しく説明しています。
後半になると、かなりの上級者向けの内容になっていますが、
完全に理解する必要はないので、最後まで読み切るようにして下さい。


メニューとツールバーの操作

この項目名についてはは、公式テキストにも書かれていますが2003以前の名称になっています。

以下では、
セルを右クリックした時のコンテキストメニュー(ショートカットメニュー)について記載します。


シートモジュールに以下を追加します。

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
  Dim cmdBra1 As CommandBarControl
  Dim cmdBra2 As CommandBarControl
  '標準状態にリセット
  CommandBars("Cell").Reset
  '全てのメニューを一旦削除
  For Each cmdBra1 In CommandBars("Cell").Controls
    cmdBra1.Visible = False
  Next
  '以下で、新規のメニューを追加
  Set cmdBra1 = CommandBars("Cell").Controls.Add()
  With cmdBra1
    .Caption = "AA"
    .FaceId = 2
    .OnAction = "AA"
  End With
  Set cmdBra1 = CommandBars("Cell").Controls.Add(Type:=msoControlPopup)
  With cmdBra1
    .Caption = "BB"
    .BeginGroup = True
  End With
  Set cmdBra2 = cmdBra1.Controls.Add()
  With cmdBra2
    .Caption = "BB1"
    .FaceId = 3
    .OnAction = "BB1"
  End With
  Set cmdBra2 = cmdBra1.Controls.Add()
  With cmdBra2
    .Caption = "BB2"
    .FaceId = 4
    .Tag = "説明"
    .OnAction = "'BB2(""" & .Tag & """)'"
  End With
  CommandBars("Cell").ShowPopup
  CommandBars("Cell").Reset
  Cancel = True
End Sub

覚えるべきプロパティ・メソッドを太字にしています。

.OnAction = "'BB2(""" & .Tag & """)'"
これは、OnActionで起動されるマクロに引数を渡しています。
ただし、記述が難しいので試験には出ません。


標準モジュールに以下を追加

Sub AA()
  ActiveCell.Value = "AA"
End Sub
Sub BB1()
  ActiveCell.Value = "BB1"
End Sub
Sub BB2(ByVal argTag)
  ActiveCell.Value = argTag
End Sub

OnActionで呼ぶプロシージャーは、必ず標準モジュールに作成します。


右クリックしてみましょう

シートモジュールを追加したシートでセルを右クリックすると



このように表示され、メニューをクリックすると、対応する文字がセルに入るようになります。



CommandBarオブジェクト

コマンド バーを表します。
CommandBarオブジェクトは、CommandBarsコレクションのメンバーです。

CommandBars("Cell")
CommandBarsコレクションの中から、"Cell"という名前のCommandBarオブジェクトを取得しています。
これが、右クリックで表示されるメニューになります。
"Cell"以外も沢山ありますが、試験には出ないはずです。
以下は、全てのCommandBarsの名前をイミィディエイトに出力しています。

Sub sample()
  Dim obj
  For Each obj In CommandBars
    Debug.Print obj.Name
  Next
End Sub

この右クリックメニューな中に、
Control(一つ一つのメニュー)の集まりとしてのControlsコレクションがあります。
以下は、全てのControlsの見出しをイミィディエイトに出力しています。

Sub sample()
  Dim obj
  For Each obj In CommandBars("Cell").Controls
    Debug.Print obj.Caption
  Next
End Sub

メニューを追加する時は、Controls.Addメソッドを使います。
メニューを削除する時は、Controls(インデックスまたは名前を指定).Deleteメソッドを使います。


コマンドバー.Controls.Add()

Addに指定する引数です。

名前 説明
Type 指定したコマンド バーに追加するコントロールの種類を指定します。
使用できる定数は、MsoControl クラスの
msoControlButton、msoControlEdit、msoControlDropdown、msoControlComboBox、msoControlPopup
のいずれかです。
Id 組み込みのコントロールを表す整数を指定します。
この引数を1に設定するか省略すると、指定した種類の空白のカスタム コントロールがコマンド バーに追加されます。
Parameter 組み込みのコントロールの場合、この引数はコンテナー アプリケーションでコマンドを実行するときに使用されます。
カスタム コントロールの場合、この引数を使用して、Visual Basic のプロシージャに情報を渡したり、Tag プロパティの 2 番目の値のようなコントロールの情報を格納することができます。
Before コマンド バーにおける新しいコントロールの位置を表す数字を指定します。
新しいコントロールは、指定した位置にあるコントロールの直前に挿入されます。
この引数を省略すると、コントロールは指定したコマンド バーの末尾に追加されます。
Temporary True を指定すると、新しいコントロールが一時的なものになります。
このコントロールは、コンテナー アプリケーションの終了と同時に自動的に削除されます。
この引数を省略すると、既定値の False になります。

上記サンプルでは、"BB"は親メニューになりますので、
Type:=msoControlPopup
これを指定しています。

省略している場合は、
Type:=msoControlButton
これが規定となります。


コントロールのプロパティについて

Caption
メニューに表示する文字列を設定します。

OnAction
起動するプロシージャ名を文字列で指定します。

FaceId
Type:=msoControlButtonの場合には、アイコンを指定できます。
この番号と実際のアイコンについては、「エクセルのアイコン取得」を参照して下さい。

State
公式テキストに書かれていますが、
このプロパティでチェツクを付ける方法が紹介されています。
実務で使う場面が想像出来ないのですが、一応おぼえておきましょう。

上記の使用例では、右クリックのイベント内なのでStateの切替は使えません。

Tag
任意の説明を設定できます。


【業務改善の実務】

ユーザーが入力しやすいように、ユーザーフォームを用意することは必用です。
ただし、
むやみにユーザーフォームを使えば良いという事も無く、
シートの形式を工夫すれば済む場合も多々ありますので、良く考えて設計するべきです。

凝ったユーザーフォームにイベントを大量に組み込んでいくと、
マクロがとても複雑になり、後々のメンテに苦労することになります。
VBAには、適切なコメントを書き込んでおくとか、
関連するイベントは、プロシージャ内の近くにまとめておく等の工夫は必ずしておくべきです。

右クリックは、
ボタンが配置出来ない時や、機能が多様になっている場合の選択方法としては有効な手段です。
VBAコードは定型的なものになるので、コピペで使い回せるようにしておきましょう。


【本サイト内の関連ページ】





同じテーマ「MOS VBAエキスパート対策」の記事

プロシージャ
イベント
ステートメント(スタンダード)
関数
エラーへの対処
APIとOLEオートメーション
変数と配列
レジストリの操作
ファイルの操作
ユーザーフォームとメニューの操作
VBAスタンダード試験対策まとめ

新着記事 ・・・新着記事一覧を見る

数値範囲で表検索するVLOOKUP近似一致|エクセル関数超技(10月5日)
エクセルVBAでのシート指定方法|VBA技術解説(9月8日)
VBAのクラスとは(Class,Property,Get,Let,Set)|VBA技術解説(8月28日)
VBAこれだけは覚えておきたい必須基本例文10|VBA技術解説(8月22日)
VBAの省略可能な記述について|ExcelマクロVBA技術解説(8月11日)
複数条件判定を行う時のコツ|ExcelマクロVBA技術解説(7月11日)
For Next の使い方いろいろ|VBA技術解説(6月14日)
VBAを定型文で覚えよう|ExcelマクロVBA技術解説(3月26日)
VBAスタンダード試験対策まとめ|MOS VBAエキスパート対策(3月16日)
ユーザーフォームとメニューの操作|MOS VBAエキスパート対策(3月14日)

アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.変数とデータ型(Dim)|ExcelマクロVBA入門
4.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
5.RangeとCellsの使い方|ExcelマクロVBA入門
6.定数と型宣言文字(Const)|ExcelマクロVBA入門
7.ひらがな⇔カタカナの変換|エクセル基本操作
8.マクロって何?VBAって何?|ExcelマクロVBA入門
9.繰り返し処理(For Next)|ExcelマクロVBA入門
10.とにかく書いて見よう(Sub,End Sub)|VBA入門



  • >
  • >
  • >
  • ユーザーフォームとメニューの操作

  • このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


    記述には細心の注意をしたつもりですが、
    間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
    なお、掲載のVBAコードは自己責任で使ってください。万一データ破損等の損害が発生しても責任は負いません。





    このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

    本文下部へ

    ↑ PAGE TOP